Wor2Dec - Converte una word in stringa di cinque caratteri decimali Ascii - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

Wor2Dec [25 di 54]

	Converte il numero esadecimale a 16 bit nella corrispondente stringa composta fino a 5 caratteri ASCII *decimali* e la mette a video nella posizione di stampa corrente.
	La stringa posta a video sarà composta esclusivamente da caratteri corrispondenti a simboli del sistema di numerazione decimale, cioè *solo* dai numeri da "0" a "9.

La Procedura si chiama in questo modo:

In ingresso bisogna predisporre:

AX con il numero esadecimale a 16 bit da convertire in stringa decimale e da mettere poi a video.

La seguente Area di Testo mostra il Modulo varie06 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

Wor2Dec / varie06

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : Wor2Dec.ASM                                                 ³
;³ MODULO      : varie06  (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.ASM)               ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : gennaio  2003                                               ³
;³ AGGIORNAMEN.: gennaio  2003                                               ³
;³ DESCRIZIONE : Trasforma la Word esadecimale fornita in  AX  nei  caratteri³
;³               ASCII corrispondenti,  ponendoli a video  nella posizione di³
;³               stampa corrente con l'attributo di Colore  specificato nella³
;³               variabile [ATTRIB]; gli "0" non  significativi  non  vengono³
;³               stampati.                                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        PUBLIC  Wor2Dec
        PUBLIC  Byt2Dec
        PUBLIC  STAasci
        EXTRN   BIOchr1:NEAR
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
Wor2Dec proc    NEAR
        PUSH    AX            ;¿Salva i Registri usati  dalla Procedura,  com-
        PUSH    BX            ;³preso il valore da convertire, passato in  in-
        PUSH    DX            ;Ùgresso in AX
        CMP     AX,10000      ;¿Se il numero esadecimale in ingresso  Š minore
        JC      Wor2_0        ;Ùdi 10000 la successiva divisione viene evitata
        MOV     DX,0000H      ;¿(DX,AX=0000XXXX):(BX=10000)=AX, resto DX
        MOV     BX,10000      ;³Prepara il divisore a 10000
        DIV     BX            ;³Esegue la divisione
        CALL    STAasci       ;ÙStampa il valore delle Decine di Migliaia
        MOV     AX,DX         ;¿Sposta in AX il  Resto  RRRR  della  divisione
        JMP     SHORT Wor2_1  ;Ùprecedente da dividere  nella  fase successiva
Wor2_0: CMP     AX,1000       ;¿Se il numero esadecimale in ingresso  Š minore
        JC      Byt2_0        ;Ùdi 1000  la successiva divisione viene evitata
Wor2_1: MOV     DX,0000H      ;¿(DX,AX=0000XXXX):(BX=1000)=AX, resto DX
        MOV     BX,1000       ;³Prepara il divisore a 1000
        DIV     BX            ;³Esegue la divisione
        CALL    STAasci       ;ÙStampa il valore delle Migliaia
        MOV     AX,DX         ;¿Sposta in AX il  Resto  RRRR  della  divisione
        JMP     SHORT Byt2_1  ;Ùprecedente da dividere nella  fase  successiva

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : Byt2Dec.ASM                                                 ³
;³ MODULO      : varie06  (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.ASM)               ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : gennaio  2003                                               ³
;³ AGGIORNAMEN.: gennaio  2003                                               ³
;³ DESCRIZIONE : Trasforma il Byte esadecimale fornito in  AL  nei  caratteri³
;³               ASCII  corrispondenti, ponendoli a video  nella posizione di³
;³               stampa corrente con l'attributo di Colore  specificato nella³
;³               variabile [ATTRIB]; gli "0" non  significativi  non  vengono³
;³               stampati.                                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Byt2Dec proc    NEAR
        PUSH    AX            ;¿Salva i Registri usati  dalla Procedura,  com-
        PUSH    BX            ;³preso il valore da convertire, passato in  in-
        PUSH    DX            ;Ùgresso in AL
        MOV     AH,00H        ;*Formatta il dividendo al valore AX=00XX
Byt2_0: CMP     AX,100        ;¿Se il numero esadecimale in ingresso  Š minore
        JC      Byt2_2        ;Ùdi  100 la  successiva divisione viene evitata
Byt2_1: MOV     BL,100        ;¿Prepara il divisore a 100
        DIV     BL            ;³Divide AX=00XX per BL=100 (AX:BL=AL, resto AH)
        CALL    STAasci       ;ÙStampa il valore delle Centinaia
        MOV     AL,AH         ;¿Sposta in AL il Resto RR della divisione  pre-
        MOV     AH,00H        ;³cedente da  dividere  nella  fase  successiva,
        JMP     SHORT Byt2_3  ;Ùformattando il dividendo al valore AX=00RR
Byt2_2: CMP     AX,10         ;¿Se il numero esadecimale in ingresso  Š minore
        JC      Byt2_4        ;Ùdi 10 la successiva  divisione  viene  evitata
Byt2_3: MOV     BL,10         ;¿Prepara il divisore a 10
        DIV     BL            ;³Divide AX=00XX per BL=10  (AX:BL=AL, resto AH)
        CALL    STAasci       ;³Stampa il valore delle Decine
        MOV     AL,AH         ;*Prepara in AL la cifra delle Unit…
Byt2_4: CALL    STAasci       ;*Stampa il valore delle Unit…
        POP     DX
        POP     BX
        POP     AX
        RET
Byt2Dec ENDP
Wor2Dec ENDP
        ;---------------------------------------------------------------------
STAasci proc    NEAR          ;¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        PUSH    AX            ;³³    Accessorio delle procedure Precedenti   ³
        ADD     AL,30H        ;³ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        CALL    BIOchr1       ;³    Stampa il valore ASCII del numero in AL
        POP     AX            ;³
        RET                   ;³
STAasci ENDP                  ;Ù
_prog   ENDS
        END

L'analisi del codice ci consente di mettere in evidenza la sua brillante operatività; i singoli caratteri del risultato vengono posti a video in stretta sequenza, per intercessione della Procedura BIOchr1, a sua volta chiamata dalla STAscii, definita internamente.

Il corretto funzionamento di questa Procedura è dunque assicurato solo se, prima di chiamarla, si predispone almeno il registro AX con il valore a 16 bit del numero da convertire.

Potrebbe essere necessario fissare anche le coordinate della posizione di stampa (con M_CURSOR) e il colore desiderato (con M_COLOR); ma entrambe queste informazioni non sono strettamente necessarie:

	se non si specificano le *coordinate* la procedura collocherà il carattere nella posizione di stampa corrente (là dove lampeggia il cursore)
	se non si specifica il *colore* la procedura prende per buono il codice presente in quel momento nella variabile ATTRIB.

Per esempio, per mettere a video la stringa corrispondente all'interpretazione Ascii del numero AB12H, in colore giallo su sfondo blu (1EH) nel punto di coordinate riga=10 e colonna=20, si deve scrivere questa sequenza di istruzioni:

	Libreria GiobeASM			Wor2Dec
	25 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default