RAMcorn - Organizza la stampa completa di un'area corniciata a livello ramvideo - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

RAMcorn [47 di 54]

Stampa una cornice con tutte le caratteristiche necessarie per un ottimo servizio, direttamente a livello RamVideo.

La Procedura si chiama in questo modo:

In ingresso bisogna predisporre:

	AL con la larghezza (espressa in caratteri)
	AH con l'altezza (espressa in caratteri)
	DL con la coordinata colonna dell'angolo in alto a destra
	DH con la coordinata riga dell'angolo in alto a destra
	BH con valore BH=01 se con ombreggiatura o BH=00 se senza ombreggiatura
	BL con valore BL=00 se a tratto semplice o BL=01 se a tratto doppio
	CX con l'indirizzo di Offset della Pagina Video alternativa in cui salvare l'area sottostante alla cornice, sempre di tipo 1000H, 2000H, 3000H, ..
	la variabile ATTRIB con il codice di colore desiderato

La seguente Area di Testo mostra il Modulo ram04 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

RAMcorn / ram04

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURA  : RAMcorn.ASM                                                   ³
;³MODULO     : RAM04                (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.ASM)     ³
;³AUTORE     : Giorgio OBER                                                  ³
;³VERSIONE   : maggio 1995                                                   ³
;³AGGIORNAMEN: gennaio  2003                                                 ³
;³DESCRIZIONE: Stampa una CORNICE con ombreggiatura (se BH=01) o senza(BH=00)³
;³             a tratto semplice (se BL=00) o doppio (BL=01),  di  dimensioni³
;³             esterne AL=larghezza/AH=altezza  (in  caratteri),  nel  colore³
;³             predisposto nella variabile [ATTRIB]; il suo angolo  superiore³
;³             deve essere fornito in DH=riga/DL=colonna.                    ³
;³                                                                           ³
;³             Da notare che il contenuto dell'area di video interessata dal-³
;³             la finestra cosi ricavata  Š  SALVATO NELLE CORRISPONDENTI PO-³
;³             POSIZIONI della PAGINAx dell'AREA VIDEO con OFFSET passato me-³
;³             diante il registro CX, sempre del tipo 1000H, 2000H, 3000H,...³
;³ÚÄÄÄÄÄÄÄÄÄÄ¿ Per  favorire  la gestione  dell'ombreggiatura della  finestra³
;³³  NB.:    ³ l'area salvata nella pagina  alternativa  Š  in realt…  un po'³
;³ÀÄÄÄÄÄÄÄÄÄÄÙ pi—  grande (2 colonne e una riga in pi— ).                 ³
;³                                                                           ³
;³              ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿    ³
;³              ³                                                       ³ÛÛ  ³
;³              ³                                                       ³ÛÛ  ³
;³              ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÛÛ  ³
;³                ÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛÛ  ³
;³                                                                           ³
;³             Il recupero dei caratteri  salvati  nella  pagina  alternativa³
;³             deve esser fatto con la procedura "RAMrecup", alla quale devo-³
;³             no essere passati rigorosamente gli stessi parametri.         ³
;³                                                                           ³
;³ÚÄÄÄÄÄÄÄÄÄÄ¿ Il programma che utilizza questa procedura deve  occuparsi  di³
;³³NB:       ³ predisporre in fase di  inizializzazione  il  SEGMENTO  ES  al³
;³³          ³ valore BUFdis; l'uso dell'istruzione "STOSW" impone inoltre la³
;³³          ³ presenza della flag di direzione a "0";  all'inizio  del  pro-³
;³³          ³ gramma che utilizza questa procedura Š  necessario  assicurare³
;³³          ³ la presenza delle seguenti istruzioni:                        ³
;³³          ³ ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³³          ³ ³CALL    MODEtest      ;Inizializza le variabili VIDEO       ³³
;³³          ³ ³CLD                   ;Impone  l'incremento  degli indirizzi³³
;³³          ³ ³MOV     AX,CS:[BUFdis];In ES:DI il puntatore del  primo byte³³
;³³          ³ ³MOV     ES,AX         ;associato alla zona della  RAM  video³³
;³ÀÄÄÄÄÄÄÄÄÄÄÙ ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    ATTRIB:BYTE
        EXTRN    RAMchr:NEAR
        EXTRN    RAMcur:NEAR
        EXTRN    RAMpiu:NEAR
        if1
          include  GIOBE.MAC
        endif
        PUBLIC   RAMcorn
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
ombra    DB     01H           ;La finestra Š stampata per default con "EFFETTO
                              ;OMBRA"; tuttavia ponendo  la  variabile  PUBLIC
                              ;[ombra] ad un valore uguale a 00H  Š  possibile
                              ;eliminare questa caratteristica.
singolo  DB     'ÚÄ¿³ÀÙ'      ;Set di caratteri per cornice a tratto  SEMPLICE
doppio   DB     'ÉÍ»ºÈ¼'      ;Set di caratteri per cornice  a  tratto  DOPPIO
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
RAMcorn proc    NEAR
        PUSH    BX
        MOV     BL,80
        SUB     BL,AL
        ADD     BL,BL
        MOV     BH,00H
        RAM_cur DH,DL
        PUSH    DI
        PUSH    DS
        PUSH    BX
        SUB     BX,4
        PUSH    ES
        POP     DS
        MOV     SI,DI
        ADD     DI,CX
        MOV     CL,AH
        INC     CL
        MOV     CH,00H
WIND_0: PUSH    CX
        MOV     CH,00H
        MOV     CL,AL
        ADD     CL,2
        CLD
        REP     MOVSW
        POP     CX
        ADD     SI,BX
        ADD     DI,BX
        LOOP    WIND_0
        POP     DX
        POP     DS
        POP     DI
        POP     BX
        MOV     CS:[ombra],BH
        LEA     SI,singolo
        CMP     BL,00H
        JZ      WIND_1
        LEA     SI,doppio
WIND_1: MOV     CH,00H
        MOV     BX,DX
        MOV     BX,DX
        PUSH    AX
        MOV     CL,AL
        SUB     CL,02H
        MOV     AL,CS:[SI]
        CALL    RAMchr
        MOV     AL,CS:[SI+1]
        CALL    RAMpiu
        MOV     AL,CS:[SI+2]
        CALL    RAMchr
        POP     AX
        ADD     DI,BX
        MOV     CL,AH
        SUB     CL,02H
        SUB     BX,4
WIND_2: PUSH    CX
        PUSH    AX
        MOV     CL,AL
        SUB     CL,02H
        MOV     CH,00H
        MOV     AL,CS:[SI+3]
        CALL    RAMchr
        MOV     AL," "
        CALL    RAMpiu
        MOV     AL,CS:[SI+3]
        CALL    RAMchr
        CMP     Byte Ptr CS:[ombra],01H
        JNZ     WIND_4
        INC     DI
        MOV     Byte Ptr ES:[DI],07H
        ADD     DI,2
        MOV     Byte Ptr ES:[DI],07H
        INC     DI
        JMP     SHORT  WIND_5
WIND_4: ADD     DI,4
WIND_5: ADD     DI,BX
        POP     AX
        POP     CX
        LOOP    WIND_2
        PUSH    AX
        MOV     CL,AL
        SUB     CL,02H
        MOV     AL,CS:[SI+4]
        CALL    RAMchr
        MOV     AL,CS:[SI+1]
        CALL    RAMpiu
        MOV     AL,CS:[SI+5]
        CALL    RAMchr
        CMP     Byte Ptr CS:[ombra],01H
        JNZ     WIND_6
        INC     DI
        MOV     Byte Ptr ES:[DI],07H
        ADD     DI,2
        MOV     Byte Ptr ES:[DI],07H
        INC     DI
        JMP     SHORT  WIND_7
WIND_6: ADD     DI,4
WIND_7: ADD     BX,4
        ADD     DI,BX
        INC     DI
        POP     AX
        MOV     CL,AL
        MOV     CH,00H
        CMP     Byte Ptr CS:[ombra],01H
        JNZ     WIND_9
WIND_8: MOV     Byte Ptr ES:[DI],07H
        ADD     DI,2
        LOOP    WIND_8
WIND_9: RET
RAMcorn ENDP
_prog   ENDS
        END

L'analisi del codice mette in evidenza la grande potenza di questa preziosissima Procedura; il suo compito è quello di stampare una finestra:

	costituita da spazi, nel colore di primo piano (quello dei pixel che formano il carattere) e il colore dello sfondo (quello dei pixel rimanenti), sulla base dello schema descritto in questa pagina e comunque assunto dalla variabile locale ATTRIB, predisposta dal programmatore nella zona detta area destinata ai dati del programma.
	a partire dall'angolo DH (riga in alto a sinistra, scelta tra 0 e 24), DL (colonna in alto a sinistra, scelta tra 0 e 79)
	con dimensioni AL (lunghezza) e AH (altezza), scelte rispettivamente tra 1 e 25 e tra 1 e 80
	con bordo (cornice) a a tratto semplice o doppio
	con (a piacere) l'effetto ombra
	provvede a salvare automaticamente i caratteri sottostanti nella pagina alternativa della Ram Video indicata da CX
	per favorire la gestione dell'ombreggiatura della finestra l'area salvata nella pagina alternativa è in realtà un po' più grande (2 colonne e una riga in più).
	per ripristinare l'area originale è sufficiente chiamare la Procedura RAMrecup, rigorosamente con gli stessi parametri; l'operazione è del tutto automatica.

La stampa dei caratteri è comunque eseguita direttamente a livello RamVideo per l'azione della Procedura RAMchr.

Le Procedure che lavorano in RamVideo funzionano solo se il programma ASM che le utilizza ha predisposto il Segment ES al valore 0B800H; le sue prime 2 istruzioni devono perciò essere (leggi con attenzione queste ulteriori informazioni):

	Libreria GiobeASM			RAMcorn
	47 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default