Delay - Crea un ritardo portabile e programmabile, multiplo do 55 ms, sincronizzato con il Timer di sistema 8253 - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

Delay 1/3 [28 di 54]

^{1° dicembre
2003}

Genera un ritardo programmabile, multiplo di 54,925493 ms, in funzione del numero passato in ingresso.

Il ritardo minimo di circa 55 ms può costituire una limitazione: in certe applicazioni può effettivamente risultare troppo grande; in compenso i ritardi generati sono precisi, affidabili e soprattutto portabili (cioè completamente svincolati dalla velocità del processore e consumabili in modo uguale su tutti i computer), anche con i più moderni sistemi operativi (Windows 2000/NT/XP).

Sulla base di questa Procedura ho reso disponibili anche le Del_100, Del_1000, Del_1500 e Del_2000, pronte a consumare rispettivamente 0,1s, 1s, 1,5s e 2s; la Procedura DelMicro assicura, inoltre, ritardi dell'ordine del µs e del ms.

La Procedura si chiama in questo modo:

In ingresso bisogna predisporre:

CX con il numero di ritardi standard da 55ms da eseguire; con CX=18 viene generato un ritardo di 55ms*18= 1 secondo

La seguente Area di Testo mostra il Modulo varie07 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

Delay / varie07

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE   : Delay.ASM                                                    ³
;³MODULO      : varie07             (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.ASM)     ³
;³AUTORE      : Giorgio OBER                                                 ³
;³VERSIONE    : dicembre 2002                                                ³
;³AGGIORNAMEN : dicembre 2003                                                ³
;³DESCRIZIONE : Genera  un ritardo programmabile,  in  funzione  del  valore ³
;³              specificato in ingresso nel registro CX.                     ³
;³              Il ritardo prodotto Š completamente svincolato dalla veloci- ³
;³              t… del processore perchŠ utilizza le  informazioni  prodotte ³
;³              dal Timer di Sistema, un componente di vitale importanza per ³
;³              il funzionamento del Computer.                               ³
;³              I tempi del ritardo sono multipli del tempo minimo 54,925493 ³
;³              millisecondi;  questo  fatto  pu•  costituire un limite:  il ³
;³              tempo minimo di circa 55 ms  pu•  essere  troppo  grande, in ³
;³              certe applicazioni.                                          ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        PUBLIC  Delay
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
Delay   proc    NEAR
        PUSH    AX
        PUSH    BX
        PUSH    DX
        PUSH    CX            ;Copia  in  BX  il  numero  valore  del  RITARDO
        POP     BX            ;passato in ingresso in CX

;Restituisce in CX,DX il  tempo  reale  corrente
        MOV     AH,00H        ;del  giorno  assumendolo  dal  contenuto  delle
        INT     1AH           ;locazioni di sistema da 0000:046CH a 0000:046FH
                              ;cioŠ il numero a 32 bit dei TICKs prodotti nel-
                              ;l'arco della giornata

;Aggiorna con il   desiderato  numero  di  TICKs
        ADD     DX,BX         ;il valore CX,DX dei TICKs  relativi alla  prima
        JNC     Dela_00       ;lettura delle variabili di sistema da 0000:046C
        INC     CX            ;a 0000:046F

Dela_00:PUSH    CX            ;Copia in AX,BX il  numero  dei  TICKs  relativi
        PUSH    DX            ;alla prima lettura delle  variabili di  sistema
        POP     BX            ;da  0000:046C a  0000:046F,  AGGIORNATA  con il
        POP     AX            ;numero  corrispondente  al  RITARDO  desiderato

Dela_01:PUSH    AX            ;In uscita AX,BX conservano il numero  di  TICKs
        PUSH    BX            ;relativi alla prima lettura delle variabili  di
        MOV     AH,00H        ;sistema da 0000:046C a 0000:046F;  e  in  CX,DX
        INT     1AH           ;quello del tempo reale corrente;   Esempio:
        POP     BX            ;    AX,BX = 0012 3AF0 =  tempo da  raggiungere
        POP     AX            ;    CX,DX = 0011 FF3A =  tempo reale  corrente

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;³  Controlla se il valore corrente dei TICKs  ³
                              ;³  Š quello previsto dal desiderato   RITARDO ³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
                              ;Se la parte alta dei 2 numeri Š la stessa, cioŠ
                              ;se AX=CX, si controlla la parte bassa (a livel-
        CMP     AX,CX         ;lo  Dela_02);  altrimenti  AX  Š  quasi  sempre
        JZ      Dela_02       ;maggiore di 1 rispetto a CX; in questo caso  si
                              ;aspetta che le 2 parti alte  si  equivalgano (a
                              ;livello Dela_01, pi— sotto...)

PUSH    AX            ;Solo se nel frattempo Š passata  la  mezzanotte
        SUB     AX,CX         ;la differenza tra AX e CX Š diversa  da  1;  in
        CMP     AX,18H        ;questo caso infatti vale 18H, per cui la proce-
        POP     AX            ;dura va adattata alla  nuova  situazione (nella
        JNZ     Dela_01       ;parte di codice ASM qui sotto...)

PUSH    BX            ;Se nel frattempo Š  passata  la  mezzanotte  la
        SUB     BX,00B0H      ;differenza tra AX e CX Š pari a 18H; in  questo
        CMP     BX,DX         ;caso CX,DX Š passato da 001800AFH  a 00000000H,
        POP     BX            ;per cui anche la parte bassa va  adattata  alla
        JG      Dela_01       ;nuova situazione, visto che una parte del conto
        JMP     Dela_03       ;(=B0H) Š gi… stata consumata....

Dela_02:CMP     BX,DX         ;Se la parte alta dei 2 numeri Š la stessa  e la
        JG      Dela_01       ;parte bassa del tempo corrente Š  minore, BX>DX
                              ;continua l'attesa

Dela_03:POP     DX            ;
        POP     BX            ;Il ritardo Š stato consumato
        POP     AX            ;
        RET                   ;
Delay   ENDP
_prog   ENDS
        END

L'analisi del codice (puoi scorrerlo con la barra laterale) mette in evidenza la tecnica utilizzata per garantire il ritardo con esattezza:

	con l'aiuto della Funzione 00H dell'INT 1AH Bios, legge il contenuto delle 4 locazioni di sistema da 0000:046CH a 0000:046FH, contenenti il numero corrente (a 32 bit) dei Ticks prodotti nell'arco della giornata
	ne controlla poi, più volte, il valore fino al momento in cui viene raggiunto il quello nuovo, che tiene conto del ritardo desiderato.
	data la particolare struttura dell'algoritmo ho approntato una nuova (dicembre 2003) pagina con l'analisi più dettagliata.

I problemi legati alle procedure di ritardo sono concreti e pressanti: in ogni caso sembrano ora tutti risolti, con il ricorso al Timer di Sistema, un componente di vitale importanza per il funzionamento del Computer. Ad essi ho dedicato la pagina seguente.

La nostra Procedura, a partire da un dato a 16 bit (praticamente affidato al registro CX), è in grado di generare tempi di ritardo da un minimo di 54,925493 ms ad un massimo di 2¹⁶*54,925493ms = 65536*54,925493ms = 3599597ms, pari a 3600s, cioè circa 60 minuti, cioè 1 ora!

Su questa base è possibile compilare la Tabella dei valori con i quali è possibile caricare il registro CX:

ritardo	*Delay*	ritardo	*Delay*	ritardo	*Delay*
1	55 ms	16	879 ms	920	*50 s*
2	110 ms	17	934 ms	1092	*1 m*
3	164 ms	18	1 s	2294	*2 m*
4	219 ms	27	1,5 s	3277	*3 m*
5	274 ms	36	2 s	4370	*4 m*
6	329 ms	45	2,5 s	5462	*5 m*
7	384 ms	54	3 s	6554	*6 m*
8	439 ms	63	3,5 s	7647	*7 m*
9	494 ms	73	4 s	9831	*9 m*
10	549 ms	82	4,5 s	10964	*10 m*
11	604 ms	91	5 s	21848	*20 m*
12	659 ms	182	10 s	32771	*30 m*
13	714 ms	364	20 s	43695	*40 m*
14	769 ms	546	30 s	54619	*50 m*
15	824 ms	728	40 s	65536	*1 h*

	Libreria GiobeASM			Delay 1/3
	28 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default