DelMicro - Crea un ritardo portabile e programmabile, multiplo do 55 ms, sincronizzato con il Timer di sistema 8253 - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

DelMicro 1/2 [31 di 54]

	Genera un ritardo programmabile, multiplo di circa 1µs, in funzione del numero passato in ingresso.
	Il ritardo prodotto è svincolato quasi del tutto dalla velocità del processore, anche con i più moderni sistemi operativi (Windows 2000/NT/XP.

Sulla base di questa Procedura ho reso disponibili anche le Del010Mi, Del100Mi, Del200Mi, Del500Mi e Del_1, pronte a consumare rispettivamente 10 µs, 100 µs, 200 µs , 500 µs e 1 ms.

La Procedura si chiama in questo modo:

In ingresso bisogna predisporre:

BX con il numero da moltiplicare per il ritardo standard di 0,8381µs, ridotto di uno 0,5% in meno

La seguente Area di Testo mostra una parte del Modulo varie15 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

DelMicro/ varie15

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : DelMicro                                                    ³
;³ DESCRIZIONE : Predispone il CANALE2 del TIMER per generare  un IMPULSO che³
;³               va basso per un tempo proporzionale al valore della costante³
;³               di tempo predisposta in ingresso in BX.                     ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_8253_2 EQU     42H     ;TIMER 8253, LATCH di tempificazione per il CANALE 2
_8253ct EQU     43H     ;TIMER 8253, Registro di controllo
_8255_B EQU     61H     ;Interfaccia programmabile 8255, porta B
        PUBLIC  DelMicro
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
DelMicro proc   NEAR          
                              ;¿La programmazione del TIMER  inizia sempre con
                              ;³la scrittura della  "parola  di  comando"  del
        MOV     AL,0B0H       ;³suo REGISTRO di COMANDO accessibile attraverso
        OUT     _8253ct,AL    ;³la PORTA _8253ct(0043H) secondo lo schema:
                              ;³               B0H = 10 11 000 0
                              ;Ù10=Canale2,11=lett/scritt,000=Modo0,0=binario
                              
                              ;¿Il LATCH di temporizzazione (a 16 bit) Š  pre-
                              ;³disposto con il valore presente in ingresso in
        MOV     AL,BL         ;³BX, in grado di generere un impulso basso   di
        OUT     _8253_2,AL    ;³durata proporzionale, in æs; poichŠ  la  porta
        MOV     AL,BH         ;³d'accesso del LATCH Š di soli 8 bit, per scri-
        OUT     _8253_2,AL    ;³vere nel registro bisogna fare  2  accessi  di
                              ;ÙI/O, la parte bassa e poi la parte alta
        IN      AL,_8255_B    ;¿Si predispongono sulla porta _8355_B i bit che
        OR      AL,00000001B  ;³controllano l'ingresso dello speaker,  ponendo
        OUT     _8255_B,AL    ;³il bit0="1" (per abilitare il CLOCK sul CANALE
                              ;³2 del TIMER) e bit1="0" (per  disabilitare  il
                              ;Ùpassaggio del segnale verso l'altoparlante)
Mic_0_:                       ;¿¿Valore corrente del conteggio, aggiornato di
        MOV     DX,BX         ;³³volta in volta con il valore letto (all'ini-
                              ;³Ùzio vale 12, la costante da cui si parte)
                              ;³¿La lettura di  un  canale  del  TIMER  inizia
                              ;³³sempre  con  la  scrittura  della "parola  di
        MOV     AL,80H        ;³³comando" nel suo REGISTRO di  COMANDO,  sulla
        OUT     _8253ct,AL    ;³³PORTA (0043H) secondo lo schema: 80H=1000xxxx
                              ;³Ù         10=Canale2   00=lettura canale
        IN      AL,_8253_2    ;³¿
        MOV     AH,AL         ;³³Effettiva lettura  del  CANALE2:  lascia  il
        IN      AL,_8253_2    ;³³valore corrente in AX
        XCHG    AL,AH         ;³Ù
        MOV     BX,AX         ;³¿
        CMP     AX,DX         ;³³Aspetta che il conteggio passi a 0000H
        JB      Mic_0_        ;ÙÙ
                              ;¿Si predispongono sulla porta _8355_B i bit che
        IN      AL,_8255_B    ;³controllano l'ingresso dello speaker,  ponendo
        AND     AL,11111100B  ;³il bit0="0" (per disabilitare il CLOCK sul CA-
        OUT     _8255_B,AL    ;³NALE 2 del TIMER) e bit1="0" (per disabilitare
                              ;Ùil passaggio del segnale verso l'altoparlante)
        RET
DelMicro ENDP
_prog   ENDS
        END

I problemi legati alle procedure di ritardo di durata inferiore a 55 ms sembravano di difficile soluzione; alla loro analisi ho dedicato la pagina seguente.

L'analisi del codice (puoi scorrerlo con la barra laterale) mette in evidenza la tecnica utilizzata per garantire il ritardo con esattezza:

si predispone il Canale2 del Timer di Sistema per generare un impulso (Modo 000) e per contare indietro in binario; la programmazione del Timer inizia sempre con la scrittura della parola di comando del suo Registro di Controllo (porta 0043H)

per poter esercitare il servizio è poi necessario predisporre il latch di temporizzazione (a 16 bit) con il valore presente in ingresso in BX; poichè la porta d'accesso del latch è di soli 8 bit, per scriverci bisogna fare 2 accessi di I/O, prima con la parte bassa e poi con la parte alta

la scrittura della porta B dell'interfaccia 8255 (=61H) dà il comando di partenza:

ponendo il bit0=1 il clock (un segnale di 1,19318 MHz, pari ad periodo di 838,1ns) è reso disponibile in ingresso al Canale2 del Timer

ponendo il bit1=0 si evita che l'uscita del contatore venga spedita all'altoparlante, cosa ovviamente inopportuna

da questo istante il contatore comincia a decrementare il valore della costante preimpostata, ad ogni impulso di clock; contemporaneamente la sua uscita, alta a riposo, va bassa e rimane a questo livello fino al momento in cui il conteggio raggiunge il valore 0000H

il valore corrente del conteggio viene letto in continuazione in un loop d'attesa; per questo è necessario fornire ogni volta la relativa parola di comando al Registro di Controllo (porta 0043H)

per scoprire quando il conteggio raggiunge il valore 0000H ho dovuto inventarmi un non facile algoritmo di verifica: non sono infatti riuscito a rilevare lo stato logico del segnale generato dal Canale2; secondo la letteratura esso dovrebbe essere campionabile attraverso il bit5 della porta C dell'interfaccia 8255 (=62H), ma la lettura di questo registro non ha dato risultati (?!)

quando il contatore ha ultimato il suo conteggio indietro la sua uscita torna a 1

in condizioni normali il contatore viene ricaricato automaticamente con la costante ancora presente nel suo latch, ricominciando un nuovo conteggio; in questa procedura invece non è necessario: il ritardo programmato si è consumato regolarmente

un nuovo intervento sui bit della porta B dell'interfaccia 8255 (=61H) pone fine alle operazioni:

ponendo il bit0=0 il clock viene tolto dall'ingresso al Canale2 del Timer

ponendo il bit1=0 si ribadisce l'esclusione funzionale dell'altoparlante

La descrizione della Procedura mostra che la sua dipendenza dal Canale2 del Timer di Sistema non è assoluta; per controllarne il valore corrente è necessario eseguire un certo numero di istruzioni, la cui durata inquina il tempo di ritardo finale, non essendo in alcun modo prevedibile.

L'esecuzione di queste istruzioni dipende infatti dalla velocità del processore chiamato ad eseguirle; per questa ragione, sebbene sia possibile chiamare DelMicro da sola (con un consumo di tempo di circa 1µs), per evitare che le istruzioni di contorno possano incidere in misura considerevole sul ritardo effettivo, è consigliabile chiamarla con costante BX pari almeno a 10, cioè a partire da un ritardo di 10 µs.

I valori esatti di questa costante di tempo, calcolati a partire dalla durata minima (0,8381 µs) dell'impulso generato dal Canale2 del Timer, sono raccolti nella seguente tabella:

ritardo	*Delay*		ritardo	*Delay*
1	~ 1 µs	0.84 µs	96	~ 80 µs	80.5 µs
2	~ 2 µs	1.67 µs	120	100 µs	100 µs
3	~ 3 µs	2.51 µs	239	200 µs	200 µs
4	~ 3 µs	3.35 µs	478	400 µs	400 µs
5	4 µs	4.19 µs	597	500 µs	500 µs
6	5 µs	5.03 µs	1194	1 ms	1 ms
7	~ 6 µs	5.87 µs	2387	2 ms	2 ms
8	~ 7 µs	6.70 µs	4773	4 ms	4 ms
9	~ 7 µs	7.54 µs	5966	5 ms	5 ms
10	~ 8 µs	8.38 µs	11932	10 ms	10 ms
11	~ 9 µs	9.22 µs	23864	20 ms	20 ms
12	10 µs	10.0 µs	47728	40 ms	40 ms
24	20 µs	20.1 µs	59660	50 ms	50 ms
48	40 µs	40.2 µs	65535	~ 55 ms	54,9 ms
60	~ 50 µs	50.3 µs	65536	~ 55 ms	54,9 ms

Verifiche eseguite su computer di diversa velocità consigliano di applicare una riduzione dello 0,5%, per tener conto del tempo consumato nell'esecuzione delle istruzioni interne al ciclo, le uniche ad essere veramente influenti; con questa riduzione la procedura, chiamata 50000 volte, mostra sul ritardo atteso un leggero anticipo con processori veloci (es 2 GHz) e un leggero ritardo con processori lenti (es 500 MHz).

Un buon compromesso...

Non dimenticare che, comunque, pur mostrando di essere efficiente anche sui grandi numeri, questa procedura è nata per assicurare ritardi portabili per valori piccoli della costante predisposta in ingresso in BX , cioè per tempi inferiori a 55ms; per tempi superiori conviene riferirsi alla Procedura Delay e alle sue derivate, Del_100 (100ms), Del_1000 (1s), Del_1500 (1,5s) e Del_2000 (2s).

	Libreria GiobeASM			DelMicro 1/2
	31 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default