Asc2Nib - Converte in nibble un carattere esadecimale Ascii a livello BIOS - Giobe®2000

Sezione

Indirizzi Base Registri Interni
Area Comunicazione BIOS Funzioni BIOS Funzioni DOS
Prefazione Capitolo 1 Capitolo 2 Schede
Libreria ASM Libreria MAC Palestra Progetti ASM
Info Download INDICE

Libreria GIOBE.ASM

Home » Programma il Computer » Tutorial Assembly

Raccolta di Procedure ASM

Asc2Nib [20 di 54]

Converte un carattere ASCII nel nibble (numero a 4 bit) che gli corrisponde.

La Procedura è sostanzialmente definita per ottimizzare le Asc2Byt e Asc2Wor di cui è parte integrante fondamentale.

La seguente Area di Testo mostra il Modulo varie02 utilizzato per inserire la Procedura nella Libreria Giobe.ASM/LIB:

Asc2Nib / varie02

NB: se il testo contenuto nell'Area ti sembra strano (cioè se contiene
caratteri inconsueti) non hai ancora installato il font Giobe.TTF : clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURA   : Asc2Nib  (VERSIONE OTTIMIZZATA)                             ³
;³ MODULO      : varie02              (LIBRERIA C:\ARCH-LAB\BIN\GIOBE.ASM)   ³
;³ AUTORE      : Giorgio OBER                                                ³
;³ VERSIONE    : maggio 1995                                                 ³
;³ AGGIORNAMEN.: gennaio  2003                                               ³
;³ DESCRIZIONE : Converte il carattere ASCII corrispondente ad uno dei simbo-³
;³               li del sistema di numerazione esadecimale (da "0" a "9" e da³
;³               "A" a "F"); tale carattere Š puntato in ingresso da DS:SI ed³
;³               Š trasformato nel valore esadecimale 0xH a otto bit che  gli³
;³               corrisponde, lasciato in uscita in AL; il puntatore SI viene³
;³               incrementato.                                               ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN  BIObeep:NEAR
        PUBLIC  ERRORE
        PUBLIC  Asc2Nib

_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
                              ;Locazione usata per segnalare errore; se la lo-
ERRORE  DB      00H           ;cazione contiene 0FFH il valore lasciato in  AL
                              ;NON Š ATTENDIBILE
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
Asc2Nib proc    NEAR
        MOV     AL,CS:[SI]    ;Assume il carattere ASCII esadecimale corrente
        ;---------------------;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
        CMP     AL," "        ;³Se si tratta di un carattere  ASCII  di  con-³
        JC      AscX4         ;³trollo si segnala ERRORE  e  si  esce  subito³
        ;---------------------;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        JZ      AscX2         ;³Se si tratta di uno spazio lo traduce in 00H ³
        ;---------------------;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
        CMP     AL,"0"        ;³                                             ³
        JC      AscX4         ;³                                             ³
        CMP     AL,":"        ;³Qualunque carattere ASCII non appartenente ad³
        JC      AscX1         ;³uno dei seguenti intervalli si segnale ERRORE³
        CMP     AL,"A"        ;³e si esce subito:                            ³
        JC      AscX4         ;³  ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿  ³
        CMP     AL,"G"        ;³  ³"0" ö "9"  cioŠ  30H ö 39H  ¿intervalli³  ³
        JC      AscX0         ;³  ³"A" ö "F"  cioŠ  41H ö 46H  ³          ³  ³
        CMP     AL,"a"        ;³  ³"a" ö "f"  cioŠ  61H ö 66H  Ù  ammessi ³  ³
        JC      AscX4         ;³  ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ  ³
        CMP     AL,"g"        ;³                                             ³
        JC      AscX5         ;³                                             ³
        ;---------------------;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
AscX4:  CALL    BIObeep       ;³Il carattere ASCII  non  Š  autorizzato (cioŠ³
        SUB     AL,AL         ;³non Š di tipo esadecimale): si segnala  l'im-³
        MOV   CS:[ERRORE],0FFH;³missione non desiderata con un Beep, lascian-³
        JMP     SHORT Ascxtre   ;³do la variabile di procedura al valore 0FFH  ³
        ;---------------------;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
AscX5:  SUB     AL,20H        ;³Il carattere ASCII ricevuto in  AL  Š di tipo³
AscX0:  SUB     AL,07H        ;³esadecimale e quindi desiderato: in  funzione³
AscX1:  SUB     AL,10H        ;³della sua tipologia (numerica, letterale  mi-³
AscX2:  SUB     AL,20H        ;³nuscola o maiuscola) si trasforma in 0xH, con³
Ascxtre:  INC     SI            ;³"x" compreso tra "0" e "F"; il puntatore  nel³
        RET                   ;³BUFFER d'acquisizione viene incrementato.    ³
        ;---------------------;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
Asc2Nib ENDP
_prog   ENDS
        END

L'analisi del codice ci consente queste osservazioni:

converte in nibble esclusivamente un carattere ASCII corrispondente ad uno dei simboli del sistema di numerazione esadecimale, cioè tutti i numeri da "0" a "9" e le sole lettere da "A" a "F".

il carattere ASCII "x" è trasformato nel valore esadecimale 0xH a 8 bit corrispondente, lasciato in uscita in AL, a beneficio delle citate Asc2Byt e Asc2Wor.

il carattere ASCII è assunto dalla locazione puntata, in ingresso, da SI, indirizzo di Offset:

	se si tratta di uno spazio lo traduce in 00H
	se si tratta di un carattere ASCII di controllo o se non appartenente ad uno degli intervalli 0÷9, A÷F o a÷f, segnala errore con un beep e termina immediatamente il suo lavoro

provvede ad incrementare il puntatore SI , al fine di favorire l'acquisizione di ulteriori caratteri.

	Libreria GiobeASM			Asc2Nib
	20 di 54

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54

Giobe.ASM »

TUTORIAL »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default