HD44780 Visualizzatore LCD ["Dentro il Computer" di Giobe®2000]

		Tecnologia dei Cristalli Liquidi Controller/Driver HD44780-HW Controller/Driver HD44780-SW Connettore Modulo LCD Interfaccia Parallela LPT1 Applicazioni Software Progetti Hardware Download INDICE
Display LCD

Applicazioni Software

PROGETTO nÂ° 02 - 3/6 [33 di 65]

Analisi del Problema · Analisi del Codice · Procedure importanti · Schema interfaccia · Descrizione dello schema

Modulo LCD su parallela LPT1 - Editor di 2 linee, 16 chr/linea - Controller/Driver HD44780

Analisi del Codice Sorgente

L'obiettivo del progetto è quello di realizzare un Editor per il visualizzatore LCD a 2 linee ciascuna da 16 caratteri di un Modulo LCD, controllato dalla tastiera del PC e supportato da eco a video.

In sintonia con il progetto precedente, mantiene inalterate le prerogative hardware (schema elettrico e descrizione dello schema) e quelle software legate alla programmazione (tramite le linee d'uscita della porta parallela LPT1) del controller del Modulo LCD, sempre l'integrato HD44780 della Hitachi.

La parte differente consiste nella gestione dei tasti di editing e nella gestione dell'eco a video.

Il codice assembly del programma è visibile, nella sua totalità, scorrendo con la barra laterale il testo della seguente casella:

Progetto

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM    (marzo 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ NOME       : LCD1                                                         ³
;³ AUTORE     : RALLO PAOLO                                                  ³
;³ VERSIONE   : marzo 2003                                                   ³
;³ DESCRIZIONE: Programma per il collaudo  dell'Interfaccia Software/Hardware³
;³              di un Visualizzatore LCD collegato  su porta parallela LPT1. ³
;³ ÚÄÄÄÄÄÄÄÄÄÄ¿ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ bisogna prima installare il Driver Configura_LPT1; scaricalo ³
;³ ³°°°°°°°°°°³ a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP ³
;³ ³°°°NB !!°°³ la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in ³
;³ ³°°°°°°°°°°³ "finestra DOS" non produce effetto sul Display LCD)          ³
;³ ÃÄÄÄÄÄÄÄÄÄÄ´ -------------------------------------------------------------³
;³ ³°°°°°°°°°°³ In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire³
;³ ³°°°NB !!°°³ il programma Config_LPT1.EXE in ambiente Windows per attivare³
;³ ³°°°°°°°°°°³ la visibilit… dei driver installati con Configura_LPT1 !!!!! ³
;³ ÀÄÄÄÄÄÄÄÄÄÄÙ -------------------------------------------------------------³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³     Collegamenti tra Porta Parallela LPT1 e MODULO Visualizzatore LCD     ³
;ÃÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ´
;³     (378H)out/bit7 DIRETTO - pin09/PORTA PARALLELA ÄÄpin14/LCD Dato7     ³
;³     (378H)out/bit6 DIRETTO - pin08/PORTA PARALLELA ÄÄpin13/LCD Dato6     ³
;³     (378H)out/bit5 DIRETTO - pin07/PORTA PARALLELA ÄÄpin12/LCD Dato5     ³
;³     (378H)out/bit4 DIRETTO - pin06/PORTA PARALLELA ÄÄpin11/LCD Dato4     ³
;³                                                       pin10/LCD n.c.      ³
;³                                                       pin09/LCD n.c.      ³
;³                                                       pin08/LCD n.c.      ³
;³                                                       pin07/LCD n.c.      ³
;³     (37AH)out/bit0 NEGATO  - pin01/PORTA PARALLELA ÄÄpin05/LCD R/W       ³
;³     (37AH)out/bit3 NEGATO  - pin17/PORTA PARALLELA ÄÄpin06/LCD E         ³
;³     (37AH)out/bit2 DIRETTO - pin16/PORTA PARALLELA ÄÄpin04/LCD RS        ³
;³                        GND - pin18/PORTA PARALLELA ÄÂpin03/LCD GND       ³
;³                                                     ³ pin02/LCD Vcc +5V   ³
;³                                                     Àpin01/LCD GND       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
; COSTANTI DEFINITE PER IL PROGRAMMA:

ESC_     EQU     1BH     ;Codici di protocollo x la gestione LCD
        RETURN   EQU     0DH
        BACK     EQU     08H
        SPACE    EQU     20H

SU       EQU     48H
        GIU      EQU     50H
        DESTRA   EQU     4DH     ;AL = 00H
        SINISTRA EQU     4BH
        FINE     EQU     4FH
        CANC     EQU     53H

F1_      EQU     3BH

; MACRO UTILIZZATE DAL PROGRAMMA:
        if1     ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
         include  GIOBE.MAC ;(C:\ARCH-LAB\BIN\GIOBE.MAC);³
        endif   ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

M_TAB MACRO testo,colore,col,rig
              PUSH      SI
              PUSH      CX
              PUSH      AX
              PUSH      BX
              PUSH      DX
              LEA   SI,testo
              MOV   AH,colore
              MOV   DH,rig
              MOV   DL,col
              MOV   BL,DL
              CALL  TAB
              POP       DX
              POP       BX
              POP       AX
              POP       CX
              POP       SI
              ENDM

M_Ramcur MACRO colo,riga
              PUSH      DX
              MOV   DH,riga
              MOV   DL,colo
              CALL  RAMcur
              POP       DX
              ENDM

M_Copy MACRO pagina0,agir,annoloc,quanto
              PUSH  DX
              MOV   DH,agir
              MOV   DL,annoloc
              MOV   BX,pagina0
              MOV   CX,quanto
              CALL  Copy_r
              POP   DX
              ENDM

M_RECOPY_R MACRO pagina1,pagina2,aagir,aannoloc,quanta
              PUSH  DX
              PUSH  AX
              PUSH  BX
              MOV   DH,aagir
              MOV   DL,aannoloc
              MOV   AX,pagina2
              MOV   BX,pagina1
              MOV   CX,quanta
              CALL  RECopy_r
              POP   BX
              POP   AX
              POP   DX
              ENDM

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÚÄÄÄÄ¿ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³PROCEDURE ESTERNE³NEAR³UTILIZZATE dal PROGRAMMA (dalla LIBRERIA GIOBE.LIB~)³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÀÄÄÄÄÙÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN        STAsp:NEAR
        EXTRN        Acapo:NEAR
        EXTRN      BIOScls:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR

; DICHIARAZIONI (VARIABILI) PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB        ;Attributo di colore

; DICHIARAZIONI (PROCEDURE) PER I PROGRAMMI ESTERNI:
        PUBLIC  LCDasm

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³DEFINIZIONE DEL SEGMENTO DEL CODICE                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

ORG     0100H
INIZIO: JMP     LCDasm

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³AREA DESTINATA AI DATI DEL PROGRAMMA                                       ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
ATTRIB  DB 0000H
CONTA   DB 01H
CODICE  DB 00H
LIMITE  DB 00H

POSIZ   DB 00H

LCD     DB "ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿",00H ;16
        DB "³                ³",00H
        DB "³                ³",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ",01H

MEMI                      DB "ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿",00H ;24
                          DB "³                        ³",00H
                          DB "³                        ³",00H
                          DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ",01H

INTER   DB "°°°°°°°°°°°°°°°°",00H
INTER1  DB "°°°°°°°°°°°°°°°°°°°°°°°°",00H

TESTO   DB "MEMORIA  VIDEO",00H
        DB "     DD ram   ",01H
TESTO1  DB "MEMORIA INTERNA",00H
        DB "     DD ram   ",01H
TESTO2  DB "                  Interfaccia per la gestione di un display LCD                 ",00H
TESTO3  DB "                              RALLO PAOLO  VøCel                                ",00H

HELP    DB "Men— ",00H
HELP1   DB "F1",00H

COMA    DB "ÚÄÄÄÂÄÄÄÂÄÄÄÂÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÄÂÄÄÄÄÄÄÄÂÄÄÄÄÄ¿",00H
        DB "³  ³  ³  ³  ³ Canc ³ Fine ³ Backspace ³ Return ³ Space ³ Esc ³",00H
        DB "ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",01H
                                        ;29                            ;60   ;66
COMA1   DB "³   ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÂÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "³ spostati a destra di uno ³                                      ",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                                      ",01H
        DB "ÃÄÄÄÙ   ÀÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÂÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "³ spostati in basso di uno ³                                      ",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                                      ",01H
        DB "ÃÄÄÄÁÄÄÄÙ   ÀÄÄÄÁÄÄÄÄÄÄÁÄÄÂÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "³ spostati in alto di uno ³                                       ",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                                       ",01H
        DB "ÃÄÄÄÁÄÄÄÁÄÄÄÙ   ÀÄÄÄÄÄÄÁÄÄÄÄÄÂÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "³ spostati a sinistra di uno ³                                    ",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                                    ",01H
        DB "ÀÄÄÄÁÄÄÄÅÄÄÄÁÄÄÄÙ      ÃÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "        ³ cancella LCD ³                                          ",00H
        DB "        ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                                          ",01H
        DB "ÃÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÙ      ÀÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄ´",00H
        DB "³ scegli in che memoria lavorare: DDram + DDram o soltanto DDram ³",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ",01H
        DB "ÀÄÄÄÁÄÄÂÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÙ           ÃÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "       ³ cancella il carattere precedente ³                       ",00H
        DB "       ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ                       ",01H
        DB "ÃÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÙ        ÀÄÂÄÄÄÄÄÁÄÄÄÄÄÙ",00H
        DB "³ il cursore si sposta all'inizio della seconda riga ³            ",00H
        DB "ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ            ",01H
        DB "ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÅÄÄÄÄÄÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÙ       ÃÄÄÄÄÄÙ",00H
        DB "                              ³ inserisce uno spazio vuoto ³      ",00H
        DB "                              ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ      ",01H
        DB "ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÁÄÄÄÄÄÄÄÄÄÄÄÁÄÂÄÄÄÄÄÄÁÄÄÄÄÄÄÄÙ     ³",00H
        DB "                                            ³ Esci dal programma ³",00H
        DB "                                            ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ",01H,03H

COPY    DB "Copyright (c) Rallo Paolo",00H
PAUSA   DB "!!!!!!!!!ATTENDI!!!!!!!!!",01H

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³  AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

DESKTOP:CALL    BIOScls
        CALL    VIA_cur

MOV     AX,0B800H
        MOV     ES,AX

M_MSGC  TESTO3,0,0,1FH
        M_MSGC  TESTO2,1,0,1FH
        M_TAB   TESTO,0FH,22,10
        M_TAB   TESTO1,0FH,44,10
        M_TAB   LCD,04H,20,12
        M_TAB   MEMI,04H,38,12
        M_MSGC  INTER,13,21,01H
        M_MSGC  INTER1,13,39,01H
        M_MSGC  INTER,14,21,01H
        M_MSGC  INTER1,14,39,01H
        M_MSGC  COPY,24,54,0FH

M_MSGC  HELP,3,0,0FH
        M_MSGC  HELP1,3,7,0AH
        M_CURSOR 4,0                    ;;;;;;;;;;;;;;;

CALL    CARICA

MOV     AX,00H
        MOV     BX,AX

CALL    SET_DYS

CALL    RICARICA

MOV     DH,13
        MOV     DL,21
        CALL    EVI

RET

CARICA: M_TAB   PAUSA,40H,29,20
        M_COPY  0BA00H,15,29,15
        RET

RICARICA:M_RECOPY_R  0B800H,0BA00H,20,29,25
         RET

RAMCUR: PUSH    AX
        PUSH    DX
        ADD     DL,DL
        MOV     AL,160
        MUL     DH
        MOV     DH,00H
        ADD     AX,DX
        MOV     DI,AX
        POP     DX
        POP     AX
        RET

TAB:    MOV     AL,CS:[SI]
        CMP     AL,00H
        JNE     TAB1
        INC     DH
        MOV     DL,BL
        INC     SI
        JMP     SHORT TAB
TAB1:   CMP     AL,01H
        JE      TAB0
        CALL    RAMcur
        MOV     ES:[DI],AX
        INC     SI
        INC     DL
        JMP     SHORT TAB
TAB0:   RET

;Il ritardo generato di circa 1 ms dipende dalla frequenza del processore
Delay__:
        PUSH    CX
        MOV     CX,0000H
Del:    PUSH    AX
        PUSH    BX
        PUSH    CX
        PUSH    DX
        POP     DX
        POP     CX
        POP     BX
        POP     AX
        LOOP    Del
        POP     CX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO < CANC > Cancella display                                        ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

CANC0:  CMP     LIMITE,0FFH
        JNE     CANC1
        M_MSGC  INTER,14,21,01H
        M_MSGC  INTER,13,21,01H
        JMP     SHORT CANC2

CANC1:  M_MSGC  INTER1,13,39,01H
        M_MSGC  INTER1,14,39,01H
        M_MSGC  INTER,14,21,01H
        M_MSGC  INTER,13,21,01H
CANC2:
        MOV     DL,21
        MOV     DH,13
        CALL    EVI
        CALL    CLEAR
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO < BACKSPACE > Cancella il carattere precedente                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

BACKS:  CMP     DL,21
        JE      BAC0

MOV     BL,62
        CMP     LIMITE,0FFH
        JNE     BAC11
        MOV     BL,36
BAC11:
        CMP     DL,BL
        JNE     BAC2
        CALL    DEVI
        CALL    RAMCUR
        MOV     AL,ES:[DI]
        MOV     Byte Ptr ES:[DI],'°'
        SUB     DI,2
        MOV     ES:[DI],AL

JMP     SHORT BAC23
BAC2:
        CALL    DEVI
        PUSH    DX
BAC21:  CALL    GESTLIM
        MOV     AL,ES:[DI]
        PUSH    DX
        DEC     DL
        CALL    GESTLIM

MOV     ES:[DI],AL
        POP     DX
        CMP     DL,BL
        JE      BAC22
        INC     DL
        JMP     SHORT BAC21
BAC22:
        CALL    RAMCUR
        MOV     Byte Ptr ES:[DI],'°'
        POP     DX
BAC23:  DEC     DL
        CALL    EVI

CALL    CARICA

CALL    BACKS_D

CALL    RICARICA
BAC0:   RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO < SPACE > Aggiunge uno spazio                                    ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

SPAZIO: MOV     AL,'°'
        CALL    CARAT
        INC     DL
        CALL    EVI
        CALL    SPAZIO_
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO  < ,,, > Scorrimento cursore                                 ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

FRECCE: CALL    DEVI          ;mi muovo sul LCD con il cursore cambiando solo
        CMP     AH,SU         ;il colore degli altri caratteri
        JNE     F1
        CALL    CURS_UP
        DEC     DH
        JMP     SHORT F4

F1:     CMP     AH,GIU
        JNE     F2
        CALL    CURS_DW
        INC     DH
        JMP     SHORT F4

F2:     CMP     AH,DESTRA
        JNE     F3
        INC     DL
        CALL    CURS_DX
        JMP     SHORT F4

F3:     CMP     AH,SINISTRA
        JNE     F4
        DEC     DL
        CALL    CURS_SX
F4:
        CALL    EVI
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO <RETURN> Return                                                  ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

RETU:   CALL    DEVI
        MOV     DL,21
        MOV     DH,14
        CALL    EVI
        CALL    RETURN_
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO <FINE> Definisce il limite della Memoria Video e/o Memoria Interna ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

FIN:    CMP     LIMITE,0FFH
        JNE     FIN1              ;SI=00H  SI=FFH
        MOV     LIMITE,00H        ;SI=FFH  SI=00H
        JMP     FIN0
FIN1:   MOV     LIMITE,0FFH
        M_MSGC  INTER1,14,39,08H
        M_MSGC  INTER1,13,39,08H
        JMP     SHORT FIN2
FIN0:   M_MSGC  INTER1,13,39,01H
        M_MSGC  INTER1,14,39,01H
FIN2:           M_CURSOR 4,0                    ;;;;;;;;;;;;;;;
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO Stampa a video di un carattere                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

GESTLIM:CMP     LIMITE,0FFH   ; SI=FFH  DDRAM
        JNE     C1            ; SI=00H  LIMITI
        CALL    DDRAM
        JMP     C0
C1:     CALL    LIMITI
C0:     RET

CARAT:  CALL    GESTLIM       ;stampa il carattere e lo trasmette
        MOV     AH,01H        ;ed evidenzia la nuova posizione
        MOV     ES:[DI],AX
        RET

EVI:    PUSH    DI            ;evidenzia il carattere cambiando il colore
        CALL    GESTLIM       ;e controlla i limiti x non uscire
        INC     DI
        MOV     Byte Ptr ES:[DI],1EH
        POP     DI
        RET

DEVI:   PUSH    AX
        CALL    GESTLIM
        INC     DI
        MOV     Byte Ptr ES:[DI],01H
        POP     AX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO Definisce i limiti di DDram e/o DDram (DL=col DH=rig)            ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
;           21             36  39                    62
;           ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;       00H ³     DDram      ³³         DDram          ³ 13   40 28H
;    64 40H ³                ³³                        ³ 14  104 68H
;           ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

LIMITI: CMP     DL,20         ;se DL=20  DL=62
        JNE     L1               ;se DH=12  DH=14
        MOV     DL,62            ;se DH=15  DH=13
        CMP     DH,14
        JNE     L8            ;se DL=63  DL=21
        DEC     DH               ;se DH=12  DH=14
        JMP     SHORT L1         ;se DH=115  DH=13
L8:     INC     DH
L1:     CMP     DL,63
        JNE     L2
        MOV     DL,21
        CMP     DH,14
        JNE     L7
        DEC     DH
        JMP     SHORT L2
L7:     INC     DH
L2:     CMP     DL,37
        JNE     ltre
        MOV     DL,39
ltre:     CMP     DL,38
        JNE     L4
        MOV     DL,36
L4:     CMP     DH,12
        JNE     L5
        MOV     DH,14
L5:     CMP     DH,15
        JNE     L6
        MOV     DH,13
L6:     CALL    RAMcur
        RET

DDRAM:  CMP     DL,20         ;se DL=20  DL=36
        JNE     D1               ;se DH=12  DH=14
        MOV     DL,36            ;se DH=15  DH=13
        CMP     DH,14
        JNE     D8            ;se DL=37  DL=21
        DEC     DH               ;se DH=12  DH=14
        JMP     SHORT D1         ;se DH=15  DH=13
D8:     INC     DH
D1:     CMP     DL,37
        JNE     D2
        MOV     DL,21
        CMP     DH,12
        JNE     D7
        DEC     DH
        JMP     SHORT D2
D7:     INC     DH
D2:     CMP     DH,12
        JNE     D5
        MOV     DH,14
D5:     CMP     DH,15
        JNE     D6
        MOV     DH,13
D6:     CALL    RAMcur
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO < ESC > USCIRE                                                   ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
        
ESCI:   CALL    EXIT
        MOV     AL,00H
        MOV     BL,AL
        CALL    PARAL_0378H
        CALL    PARAL_037AH
        PUSH    AX
        CALL    RIP_cur
        MOV     DH,23
        MOV     DL,0
        CALL    SET_cur
        POP     AX
        MOV     AH,4CH
        INT     21H
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ SERVIZIO < F1 > Men—                                                      ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

Men—:   M_COPY  0B900H,3,0,480

M_TAB   COMA,0FH,7,3
        M_COPY  0BA00H,5,0,240
        M_TAB   COMA1,0FH,7,5

PUSH    AX
        PUSH    BX
        PUSH    DX
        LEA     SI,COMA1
        MOV     AH,0FH
        MOV     DH,5
        MOV     DL,7
        MOV     BL,DL
        CALL    TAB
        POP     DX
        POP     BX
        POP     AX

MOV     DL,8
        CALL    COLORA

TASMEN: CALL    KEYWAIT

CMP     AL,ESC_
        JE      G0

CMP     AL,00H
        JNE     TASMEN

GEST:   CMP     AH,DESTRA
        JNE     G0

INC     CONTA
        M_RECOPY_R 0B800H,0BA00H,5,0,240

PUSH    AX
        PUSH    BX
        PUSH    DX
        INC     SI
        CMP     Byte Ptr CS:[SI],03H
        JNE     G1
        LEA     SI,COMA1
        MOV     CONTA,01H

G1:     MOV     AH,0FH
        MOV     DH,5
        MOV     DL,7
        MOV     BL,DL
        CALL    TAB
        POP     DX
        POP     BX
        POP     AX

CALL    DECOLOR
        INC     DL
        CMP     DL,67
        JNA     G
        MOV     DL,8
G:      CALL    COLORA

G0:     CMP     AL,ESC_
        JE      M0
        CMP     AH,SINISTRA
        JNE     TASMEN
        DEC     CONTA
        CMP     CONTA,00H
        JNE     G2

LEA     SI,COMA1
        ADD     SI,1809
        MOV     CONTA,0AH
        JMP     SHORT G3

G2:     SUB     SI,401

G3:     PUSH    AX
        PUSH    BX
        PUSH    DX
        M_RECOPY_R 0B800H,0BA00H,5,0,240
        MOV     AH,0FH
        MOV     DH,5
        MOV     DL,7
        MOV     BL,DL
        CALL    TAB
        POP     DX
        POP     BX
        POP     AX

CALL    DECOLOR
        CALL    SCALA
        CALL    COLORA
        JMP     TASMEN

M0:     M_RECOPY_R  0B800H,0B900H,3,0,480
        MOV     CONTA,01H
        RET

Copy_r: CALL    RAMcur
        MOV     AX,ES:[DI]
        PUSH    ES
        MOV     ES,BX
        MOV     ES:[DI],AX
        POP     ES
        INC     DL
        CMP     DL,80
        JNE     C_3
        MOV     DL,0
        INC     DH
C_3:    LOOP    Copy_r
        RET

RECopy_r:
        MOV     ES,AX
C_2:    CALL    RAMcur
        MOV     AX,ES:[DI]
        PUSH    ES
        MOV     ES,BX
        MOV     ES:[DI],AX
        POP     ES
        INC     DL
        CMP     DL,80
        JNE     C_4
        MOV     DL,0
        INC     DH
C_4:    LOOP    C_2
        MOV     AX,0B800H
        MOV     ES,AX
        RET

COLORA: PUSH    AX
        MOV     DH,4
        MOV     BL,DL
COLO1:  CALL    RAMCUR
        MOV     AH,2FH
        MOV     AL,ES:[DI]
        CMP     AL,'³'
        JE      COL
        INC     DI
        MOV     ES:[DI],AH
        INC     DL
        JMP     SHORT COLO1
COL:    POP     AX
        RET

DECOLOR:PUSH    AX
        MOV     DL,BL
        MOV     DH,4
DCOLO1: CALL    RAMCUR
        MOV     AH,0FH
        MOV     AL,ES:[DI]
        CMP     AL,'³'
        JE      DCOL
        INC     DI
        MOV     ES:[DI],AH
        INC     DL
        JMP     SHORT DCOLO1
DCOL:   POP     AX
        RET

SCALA:  MOV     DL,BL
        SUB     DL,2
        CMP     DL,8
        JNB     SCALA0
        MOV     DL,67
SCALA0: MOV     DH,4
        CALL    RAMCUR
        MOV     AL,ES:[DI]
        CMP     AL,'³'
        JE      SCALA1
        DEC     DL
        JMP     SHORT SCALA0
SCALA1: INC     DL
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ Registro Out della parallela                                              ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

PARAL_0378H:
        PUSH    DX

MOV     DX,0378H
        OUT     DX,AL

POP     DX
        RET

PARAL_037AH:
        PUSH    DX
        PUSH    AX

MOV     DX,037AH
        MOV     AL,BL
        OUT     DX,AL

POP     AX
        POP     DX
        RET

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³ PROCEDURE PER GESTIRE IL DISPLAY LCD                                      ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

OUT_DATO:
        PUSH    AX

CALL    OUT_DATO4
        CALL    Delay__
        CALL    SWAP          ;Inverte i nibble per trasmettere tutto il dato

CALL    OUT_DATO4
        CALL    Delay__

POP     AX
        RET

OUT_DATO4:
        PUSH    AX
        PUSH    BX

;Parte alta del dato da trasmettere
        CALL    PARAL_0378H

MOV     BH,00H

;Registro 037AH per il controllo del LCD
        MOV     BL,00001011B  ;RS=0, R/W=0 (scrittura), E=0
                              ;bit2  bit0               bit3
        CALL    PARAL_037AH

CMP     CODICE,00H
        JE      OUT0
        OR      BL,00000100B  ;RS alto solo se la la CODICE Š a 0FFH
        CALL    PARAL_037AH
OUT0:                         ;se CODICE=0FFH, RS=1 trasmette un carattere
        NOP                   ;se CODICE=00H , RS=0 trasmette un codice
        AND     BL,11110111B  ;E alto: modifico il bit3 per trasmettere
        CALL    PARAL_037AH   ;        il dato
        NOP
        NOP
        NOP
        OR      BL,00001000B
        CALL    PARAL_037AH
        NOP
        POP     BX
        POP     AX
        RET

SWAP:   MOV     AH,AL
        AND     AL,0F0H
        AND     AH,0FH

SHR     AL,1
        SHR     AL,1
        SHR     AL,1
        SHR     AL,1

SHL     AH,1
        SHL     AH,1
        SHL     AH,1
        SHL     AH,1

OR      AL,AH
        RET

SET_DYS:CALL    Delay__       ;Attesa prima di iniziare
        MOV     CODICE,00H    ;il dato da trasmettere Š un codice

MOV     CX,3
SET_D1: MOV     AL,00110000B  ;8 bit 1 riga matrice 5*7
        CALL    OUT_DATO4     
        CALL    Delay__
        LOOP    SET_D1

MOV     AL,00100000B  ;4 bit 1 riga matrice 5*7
        CALL    OUT_DATO4
        CALL    Delay__       ;E' stato usato OUT_DATO4 perchŠ la parte
                              ;bassa Š 00H

MOV     AL,00101000B  ;4 bit 2 riga matrice 5*7
        CALL    OUT_DATO

MOV     AL,00001000B  ;Display OFF
        CALL    OUT_DATO

CALL    CLEAR

MOV     AL,00000110B  ;Incrementa il cursore senza shift automatico
        CALL    OUT_DATO

MOV     AL,00001101B  ;Display ON cursore pieno lampeggiante
        CALL    OUT_DATO

MOV     AL,00010100B  ;Muove cursore *******1
        CALL    OUT_DATO

CALL    CLEAR
        RET

CLEAR:  PUSH    AX

MOV     CODICE,00H
        MOV     AL,00000001B              ;Clear display
        CALL    OUT_DATO
        MOV     POSIZ,00H

POP     AX
        RET

SPAZIO_:PUSH    AX

MOV     AL,' '
        CALL    PRINT_D

POP     AX
        RET

PRINT_D:MOV     CODICE,0FFH
        CALL    OUT_DATO
        INC     POSIZ
        CALL    GEST_D
        MOV     CODICE,00H
        MOV     AL,POSIZ
        OR      AL,80H
        CALL    OUT_DATO
        RET

RETURN_:PUSH    AX

MOV     CODICE,00H
        MOV     AL,11000000B
        CALL    OUT_DATO

MOV     POSIZ,40H
        POP     AX
        RET

EXIT:   MOV     CODICE,00H
        MOV     AL,00001000B
        CALL    OUT_DATO
        RET

LIM_DC: CMP     POSIZ,28H
        JNE     LIM_DC1
        MOV     POSIZ,40H
        JMP     SHORT LIM_DC4

LIM_DC1:CMP     POSIZ,68H
        JNE     LIM_DC2
        MOV     POSIZ,00H
        JMP     SHORT LIM_DC4

LIM_DC2:CMP     POSIZ,0FFH
        JNE     LIM_DC3
        MOV     POSIZ,67H
        JMP     SHORT LIM_DC4

LIM_DC3:CMP     POSIZ,3FH
        JNE     LIM_DC4
        MOV     POSIZ,27H
LIM_DC4:RET

LIM_D:  CMP     POSIZ,10H
        JNE     LIM_1
        MOV     POSIZ,40H
        JMP     SHORT LIM_4

LIM_1:  CMP     POSIZ,50H
        JNE     LIM_2
        MOV     POSIZ,00H
        JMP     SHORT LIM_4

LIM_2:  CMP     POSIZ,0FFH
        JNE     LIM_3
        MOV     POSIZ,4FH
        JMP     SHORT LIM_4

LIM_3:  CMP     POSIZ,3FH
        JNE     LIM_4
        MOV     POSIZ,0FH
LIM_4:  RET

GEST_D: CMP     LIMITE,00H
        JNE     GESTD_1
        CALL    LIM_DC
        JMP     SHORT GESTD_2

GESTD_1:CALL    LIM_D

GESTD_2:RET

CURS_SX:PUSH    AX

MOV     CODICE,00H
        DEC     POSIZ
        CALL    GEST_D
        MOV     AL,POSIZ
        OR      AL,80H
        CALL    OUT_DATO

POP     AX
        RET

CURS_DX:PUSH    AX

MOV     CODICE,00H
        INC     POSIZ
        CALL    GEST_D
        MOV     AL,POSIZ
        OR      AL,80H
        CALL    OUT_DATO

POP     AX
        RET

CURS_UP:PUSH    AX

MOV     CODICE,00H

CMP     DH,13
        JE      UP1
        SUB     POSIZ,40H
        JMP     SHORT UP2

UP1:    ADD     POSIZ,40H

UP2:    MOV     AL,POSIZ

OR      AL,80H
        CALL    OUT_DATO

POP     AX
        RET

CURS_DW:PUSH    AX

MOV     CODICE,00H

CMP     DH,14
        JE      DW1
        ADD     POSIZ,40H
        JMP     SHORT DW2

DW1:    SUB     POSIZ,40H

DW2:    MOV     AL,POSIZ

OR      AL,80H
        CALL    OUT_DATO

POP     AX
        RET

BACKS_D:
        PUSH    DX
        PUSH    AX

CALL    CURS_SX
        MOV     BL,POSIZ
        PUSH    BX

MOV     CL,62
        CMP     LIMITE,0FFH
        JNE     BAD3
        MOV     CL,36

BAD3:   CALL    GESTLIM
        MOV     AL,ES:[DI]

CMP     DL,CL
        JE      BAD5

INC     DL

CMP     AL,'°'
        JNE     BAD2
        MOV     AL,' '
BAD2:
        PUSH    AX

MOV     AL,POSIZ
        INC     POSIZ
        CALL    GEST_D

OR      AL,80H

MOV     CODICE,00H
        CALL    OUT_DATO

POP     AX

MOV     CODICE,0FFH
        CALL    OUT_DATO

JMP     SHORT BAD3

BAD5:
        MOV     CODICE,0FFH
        MOV     AL,' '
        CALL    OUT_DATO

POP     BX
        MOV     POSIZ,BL
        MOV     AL,BL

MOV     CODICE,00H
        OR      AL,80H
        CALL    OUT_DATO

POP     AX
        POP     DX
        RET

;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
                              ;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
LCDasm  proc   NEAR           ;³      AREA DEDICATA AL MAIN PROGRAM         ³³
                              ;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ

CALL    DESKTOP       ;screen

Tasto:  CALL    KEYwait

CMP     AL,00H
        JE      FUNZ

CMP     AL,RETURN
        JNE     T3
        CALL    RETU
        JMP     SHORT Tasto

T3:     CMP     AL,BACK
        JNE     T2
        CALL    BACKS
        JMP     SHORT Tasto

T2:     CMP     AL,SPACE
        JNE     T4
        CALL    SPAZIO
        JMP     SHORT Tasto

T4:     CMP     AL,ESC_
        JNE     T1
        CALL    ESCI

T1:     CALL    CARAT
        INC     DL
        CALL    EVI

MOV     AH,00H
        PUSH    DX
        CALL    PRINT_D
        POP     DX
        JMP     SHORT Tasto

FUNZ:   CMP     AH,F1_
        JE      Menu

CMP     AH,FINE
        JNE     FUNZ1
        CALL    FIN
        JMP     SHORT Tasto

FUNZ1:  CMP     AH,48H
        JB      FUNZ2
        CMP     AH,50H
        JA      FUNZ2
        CALL    FRECCE
        JMP     SHORT Tasto

FUNZ2:  CMP     AH,CANC
        JNE     FUNZ3
        CALL    CANC0
        JMP     SHORT Tasto

FUNZ3:  JMP     SHORT Tasto

Menu:   PUSH    DX
        PUSH    SI
        CALL    Men—
        POP     SI
        POP     DX
        JMP     SHORT Tasto

LCDasm  ENDP
_prog   ENDS
        END INIZIO

La lettura può essere operata anche in Ambiente Assembler (disponibile sul Sito accedendo a questa pagina); se hai già provveduto alla sua installazione scarica il sorgente del progetto direttamente nella cartella C:\Arch-Lab\Lavoro (scegliendo il pulsante di opzione "Salva" e, come destinazione, seleziona la cartella che ti ho appena suggerito).

Ricorda: se fai click sull'icona a sinistra si apre l'Ambiente Assembly e puoi entrare in Ambiente on-line.
Scegli il pulsante di opzione "Aprire il file" o "Esegui l'applicazione" e conferma con OK.
NB: alcuni gestori di protezione (per esempio SP2 di WinXP) non ti consentono questa operazione:
in questo caso scrivi c:\arch-lab\bin\sys\assembler.pif direttamente nel campo indirizzo del Browser

Nella shell DOS aperta (o a pieno schermo) puoi iniziare una sessione di lavoro digitando MACRO LcdParal /e (con gli spazi al posto giusto !!) e conferma con Invio.

	Display LCD			PROGETTO nÂ° 02 - 3/6
	33 di 65

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65

Display LCD »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default