PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM   (aprile 2009)
SUBTTL** EsA020.ASM - Esercizi PALESTRA ASSEMBLY APPRENDISTI -  by ing. G.OBER
;/---------------------------------------------------------------------------\
;| NOME        : EsA020.ASM                                                  |
;| AUTORE      : Giorgio OBER                                                |
;| VERSIONE    : aprile 2009                                                 |
;| DESCRIZIONE : Esercizio nø 0020                                           |
;|               Legge le prime 128 locazioni della Memoria RAM  e ne  mostra|
;|               il valore  esadecimale, in gruppi di 16, come DEBUG..       |
;|               In aggiunta mostra l'indirizzo segmentato di ogni gruppo.   |
;\---------------------------------------------------------------------------/

; MACRO UTILIZZATE DAL PROGRAMMA:
        include         c:\arch-lab\bin\GIOBE.MAC

; LIBRERIA UTILIZZATA DAL PROGRAMMA [opzione WinASM altrimenti non necessaria]
        includelib      c:\arch-lab\bin\GIOBE.LIB

;PROCEDURE ESTERNE UTILIZZATE dal PROGRAMMA [NEAR, dalla LIBRERIA ~GIOBE.LIB~]
;-----------------------------------------------------------------------------
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN        STAsp:NEAR
        EXTRN        Acapo:NEAR
        EXTRN      BIOScls:NEAR
        EXTRN      BIOchr1:NEAR
        EXTRN      BIObeep:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN      Wor2Asc:NEAR

; DICHIARAZIONI (VARIABILI) PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB        ;Attributo di colore

; DICHIARAZIONI (PROCEDURE) PER I PROGRAMMI ESTERNI:
        PUBLIC  EsA020


;DEFINIZIONE DEL SEGMENTO DEL CODICE
;-----------------------------------------------------------------------------
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog
        ORG     0100H
INIZIO: JMP     EsA020


;AREA DESTINATA AI DATI DEL PROGRAMMA
;-----------------------------------------------------------------------------
ATTRIB  DB 0FH
Testo01 DB " *** Stai vedendo i primi 128 bytes della tua Ram *** ",00H
Testo02 DB " ---------------------------------------------------- ",00H
Testo03 DB " Copia i primi su un foglio e, quando esci, controlla ",00H
Testo04 DB " tu stesso con DEBUG (con il comando interno - D 0:0) ",00H
Testo05 DB " Premi  un  tasto  qualunque  per  tornare  al DOS... ",00H

;*****************************************************************************
                              ; ----------------------------------------------
EsA020  proc   NEAR           ;      AREA DEDICATA AL MAIN PROGRAM
                              ; ----------------------------------------------
;-----------------------------------------------------------------------------
                              ; Provvede   alla   cancellazione   del   video,
        CALL    BIOScls       ; posizionando il cursore alla riga0,  colonna0,
                              ; in alto a sinistra
        CALL    VIA_cur       ; Rende il  cursore invisibile
      M_msgC Testo01,00,10,1FH;
      M_msgC Testo02,01,10,1FH; Mette a video il titolo
      M_msgC Testo03,02,10,1FH;
      M_msgC Testo04,03,10,1FH;

        MOV     AX,0000       ; Crea il puntatore  al  segmento  che  desideri
        MOV     ES,AX         ; analizzare, ES:DI = 0000:0000, l'inizio RAM !!
        MOV     DI,0000       ;

        MOV     DH,10         ; Fissa la posizione di stampa iniziale
        MOV     DL,02         ; riga 10, colonna 2

        MOV     CX,8          ; Contatore delle righe da stampare (sono 8)

xxx00:  PUSH    CX            ; Ciclo esterno, per gestire le 8 righe di dati
        CALL    SET_cur       ; Fissa  dinamicamente la  posizione  di  stampa
        M_COLOR 0EH           ; Fissa il  colore  con  cui stampare la stringa
        MOV     AX,ES         ;
        CALL    Wor2Asc       ;
        MOV     AL,':'        ;
        CALL    BIOchr1       ; Stampa l'indirizzo segmentato corrente
        MOV     AX,DI         ;
        CALL    Wor2Asc       ;
        MOV     AL,' '        ;
        CALL    BIOchr1       ;

        MOV     CX,16         ; Contatore dei bytes per ogni riga (sono 16)
        M_COLOR 0FH           ; Fissa il  colore  con  cui stampare la stringa
xxx01:  MOV     AL,ES:[DI]    ; Ciclo interno, per gestire i 16 bytes per riga
        INC     DI            ;
        CALL    Byt2Asc       ; Dopo la stampa dei due caratteri ascii  corri-
        PUSH    AX            ; spondenti ai 2 nibble del byte  corrente  sono
        MOV     AL,'H'        ; aggiunti il carattere "H" (per ribadire che si
        CALL    BIOchr1       ; tratta di un valore esadecimale) e uno spazio,
        MOV     AL,' '        ; per staccare la stampa di un valore da  quella
        CALL    BIOchr1       ; del successivo
        POP     AX            ;
        LOOP    xxx01         ;
        INC     DH            ; Punta la riga successiva  e  provvede alla sua
        POP     CX            ; stampa
        LOOP    xxx00         ;
                              ; ----------------------------------------------
        M_msgC Testo05,24,10,1FH; Mette a video la frase di commiato
        CALL    KEYwait       ;


_OUT:   PUSH    AX            ; Torna al DOS con la memoria liberata e con la
        CALL    RIP_cur       ; chiusura di tutti i file; cede  il  controllo
        MOV     DH,23         ; al processo padre (generalmente COMMAND.COM);
        MOV     DL,0          ; il valore posto eventualmente  in AL prima di
        CALL    SET_cur       ; uscire pu• essere testato in  uscita  con  la
        POP     AX            ; funzione 4DH  o  mediante  la  lettura  della
        MOV     AH,4CH        ; variabile DOS "ERRORLEVEL"
        INT     21H           ;

EsA020  ENDP                  ; Chiusura della Procedura "Main Program"
_prog   ENDS                  ; Chiusura del Segmento di CODICE
        END INIZIO            ; Indirizzo dell'ultima istruzione da compilare