PAGE 66,132
TITLE** PROGRAMMA di GESTIONE di programmi ASSEMBLER  tipo COM  (ottobre 2003)
SUBTTL ** TUTORIAL ASSEMBLY  --  www.giobe2000.it   --    by ing. Giorgio OBER
;/---------------------------------------------------------------------------\
;| NOME        : Out64Lpt.ASM                                                |
;| AUTORE      : Giorgio OBER                                                |
;| VERSIONE    : ottobre 2003                                                |
;| DESCRIZIONE : Gestione  di una PORTA PARALLELA a basso livello, al fine di|
;|               controllare 64 linee d'uscita.                              |
;| /----------\ -------------------------------------------------------------|
;| |          | Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP |
;| |   NB !!  | bisogna prima installare il Driver Configura_LPT1; scaricalo |
;| |          | a:   http://www.giobe2000.it/consigli/Scarica_VediLPT_XP.htm |
;| *----------* -------------------------------------------------------------|
;| |          | Se si lavora con i Sistemi Operativi Win2000, Win NT o WinXP |
;| |   NB !!  | la SHELL DOS deve essere a "Pieno Schermo" (l'esecuzione  in |
;| |          | "finestra DOS" non produce effetto sulla Stampante)          |
;| *----------* -------------------------------------------------------------|
;| |          | In ogni caso PRIMA DI OGNI SESSIONE DOS Š necessario eseguire|
;| |   NB !!  | il programma Config_LPT1.EXE in ambiente Windows per attivare|
;| |          | la visibilit… dei driver installati con Configura_LPT1 !!!!! |
;| \----------/ -------------------------------------------------------------|
;\---------------------------------------------------------------------------/
; COSTANTI DEFINITE PER IL PROGRAMMA:
        PRNdato EQU  378H     ;Registro   dei   DATI ( USCITA )
        PRNcomd EQU  37AH     ;Registro di CONTROLLO ( USCITA )

; MACRO UTILIZZATE DAL PROGRAMMA:
        include         c:\arch-lab\bin\GIOBE.MAC

; LIBRERIA UTILIZZATA DAL PROGRAMMA [opzione WinASM altrimenti non necessaria]
        includelib      c:\arch-lab\bin\GIOBE.LIB

;PROCEDURE ESTERNE UTILIZZATE dal PROGRAMMA [NEAR, dalla LIBRERIA ~GIOBE.LIB~]
;-----------------------------------------------------------------------------
        EXTRN    CambiaCol:NEAR
        EXTRN      SET_cur:NEAR
        EXTRN      VIA_cur:NEAR
        EXTRN      RIP_cur:NEAR
        EXTRN      KEYwait:NEAR
        EXTRN      BIOSmsg:NEAR
        EXTRN      Byt2Asc:NEAR
        EXTRN       RAMcls:NEAR
        EXTRN       RAMchr:NEAR
        EXTRN       RAMcur:NEAR
        EXTRN       RAMmes:NEAR
        EXTRN       RIEMPI:NEAR
        EXTRN       RAMpiu:NEAR

; DICHIARAZIONI PER I PROGRAMMI ESTERNI:
        PUBLIC  ATTRIB
        PUBLIC  Out64Lpt

;DEFINIZIONE DEL SEGMENTO DEL CODICE
;-----------------------------------------------------------------------------
_prog   SEGMENT BYTE PUBLIC 'CODE'
        ASSUME  CS:_prog,DS:_prog

        ORG     0100H
INIZIO: JMP     Out64Lpt

;AREA DESTINATA AI DATI DEL PROGRAMMA
;-----------------------------------------------------------------------------
ATTRIB  DB   1FH
Dato_64 DD     0
        DD     0
TESTO1  DB   "Erogazione di un dato a 64 bit sulla porta parallela",00H
TESTO2  DB   "TUTORIAL ASSEMBLY  ---  www.Giobe2000.it  ---",00H
TESTO3  DB   "Quit",00H

;AREA DESTINATA ALLE PROCEDURE DEL PROGRAMMA
;/---------------------------------------------------------------------------\
;|PROCEDURA  : DeskTop                                                       |
;|DESCRIZIONE: Procedura che inizializza completamente il  piano  di  lavoro.|
;\---------------------------------------------------------------------------/
DeskTop:CALL    RAMcls        ;Pulisce lo schermo e inizializza il segmento
                              ;dedicato alla RamVideo (ES=0B800H)
        CALL    VIA_cur       ; Rende il  cursore invisibile
        M_COLOR  71H          ;
        MOV     AL,"°"        ;
        CALL    RIEMPI        ;
      RAMrepC 80," ", 0, 0,30H;
      RAMrepC 80," ",24, 0,30H;
      RAMcol  TESTO1, 0,10,3FH; Organizza il piano di presentazione
      RAMcol  TESTO2,24,10,3FH;
      RAMcol  TESTO3,24,73,30H;
        RAM_cur 24,73         ;
        M_COLOR 3FH           ;
        MOV     AL,"Q"        ;
        CALL    RAMchr        ;
        RET

;/---------------------------------------------------------------------------\
;|PROCEDURA  : Out64bit                                                      |
;|DESCRIZIONE: Procedura che provvede a fissare sulle 8  memorie  74LS374 il |
;|             dato a 64 predisposto nei registri DX,CX,BX,AX (high,...,low).|
;|             In pratica igli 8 bytes predisposti sulla porta  0378H (copia |
;|             rispettivamente di AL, AH, BL, BH, CL, CH, DL e DH)   vengono |
;|             smistati in sequenza sulle rispettive memorie numerate da 0a8 |
;|                                                                           |
;|             /-[037AH/027AH - PORTA d'USCITA dei COMANDI]-------------\    |
;|             |       | * | * | * | * |Out|Out|Out|Out|                |    |
;|             |non    \---*---*---*---*---*---*---*---/                |    |
;|             |disponib.*---*---*---/   |   |   |   |                  |    |
;|             |pin 17 Negato-----[InC]--/   |   |   |                  |    |
;|             |pin 16 ----[enable Decoder]--/   |   |                  |    |
;|             |pin 14 Negato--------------[InB]-/   \[InA]-pin 1 Negato|    |
;|             \--------------------------------------------------------/    |
;\---------------------------------------------------------------------------/
Out64bit:
        PUSH    CS            ; Prepara il puntatore  ES:DI = CS:Dato_64  alla
        POP     ES            ; zona destinata  a  memorizzare il dato binario
        LEA     DI,Dato_64    ; a 64 passato in ingresso in DX,CX,BX,AX
        CLD                   ;
        STOSW                 ;
        MOV     AX,BX         ; Memorizza in  sequenza  gli 8 bytes, dal  meno
        STOSW                 ; significativo  (disponibile  in  AL)  al   pi—
        MOV     AX,CX         ; significativo (disponibile in DH), con l'aiuto
        STOSW                 ; della  potente  STOSW (Store String Word)  che
        MOV     AX,DX         ; provvede alle operazioni: ES:[DI]<AX e DI=DI+2
        STOSW                 ;
                              ;
        LEA     DI,Dato_64    ;
        MOV     CX,8          ; /[opzionale]---------------------------------\
Out_0:  MOV     DL,32         ; | Provvede alla stampa a video dell'informa- |
        MOV     AL,8          ; | zione (8 bytes) che sta per essere spedita |
        SUB     AL,CL         ; | al  registro  DATI  della porta  parallela |
        ADD     AL,AL         ; \--------------------------------------------/
        ADD     DL,AL         ;
        M_CURSOR 13,DL        ; Notare la tecnica per stampare nella corretta
        MOV     AL,ES:[DI]    ; sequenza gli 8 bytes, dal  meno significativo
        CALL    Byt2Asc       ; al pi— significativo
        INC     DI            ;
        LOOP    Out_0         ;
                              ; Ricarica il puntatore alla zona  contenente il
        LEA     DI,Dato_64    ; il dato binario a 64 da  spedire  in  sequenza
                              ; sul Registro DATI  0378H della porta parallela
        MOV     DX,PRNdato    ; Punta il  Registro DATI 0378H  della parallela
        MOV     CX,8          ; Carica il contatore per il servizio di 8 bytes
Out_1:  MOV     AL,ES:[DI]    ; Eroga in stretta sequenza gli 8 bytes generan-
        OUT     DX,AL         ; do il clock (un breve impulso alto)  solo  per
        CALL    Clock         ; la  memoria  interessata  dal  dato  a  8  bit
        INC     DI            ; corrente; le rimanenti 3 memorie 74LS374 hanno
        LOOP    Out_1         ; tutte le linee di clock a livello "0",inattive
        RET

;/---------------------------------------------------------------------------\
;|PROCEDURA  : Clock                                                         |
;|DESCRIZIONE: Genera un impulso alto sulla linea di clock di una sola delle |
;|             memorie 74LS374 coinvolte nel progetto;  le  rimanenti  hanno |
;|             tutte le linee di clock a livello basso, disattive.           |
;|             La memoria interessata dal clock Š quella di ordine CL-n, con |
;|             n uguale al numero  di  memorie  coinvolte;  naturalmente  il |
;|             valore di CL deve essere predisposto prima della chiamata.    |
;\---------------------------------------------------------------------------/
                              ; La memoria abilitata Š puntata dall'uscita del
                              ; decoder 74LS139  puntata  dal  codice  binario
Clock:  ADD     DX,2          ; applicato sui suoi ingressi di selezione a lo-
        MOV     AL,8          ; ro volta fissati dal valore dei bit3,bit1,bit0
        SUB     AL,CL         ; (invertiti internamente) predisposto  nel  Re-
                              ; gistro di CONTROLLO 037AH cioŠ 000 per la pri-
                              ; ma memoria (in alto nello schema)  e  111  per
                              ; l'ultima (in basso nello schema)
        CMP     AL,03         ; Adatta il valore del bit3 al codice in AL:
        JBE     Clock1        ; se AL<=03 il codice Š 0x00, 0x01, 0x10 o 0x11
        OR      AL,00001000B  ; se AL>=04 il codice Š 1x00, 1x01, 1x10 o 1x11
Clock1: AND     AL,11111011B  ; L'impulso  di  clock Š  creato  effettivamente
        OUT     DX,AL         ; forzando prima a "0"  e  poi a "1" il bit2 del
        OR      AL,00000100B  ; medesimo registro; in  questo  modo si abilita
        OUT     DX,AL         ; il decoder creando un impulso basso sull'usci-
        SUB     DX,2          ; ta selezionata e il desiderato impulso alto di
        RET                   ; clock sulla memoria, per effetto dell'inverter

;*****************************************************************************
                              ; ----------------------------------------------
Out64Lpt proc   NEAR          ;      AREA DEDICATA AL MAIN PROGRAM
                              ; ----------------------------------------------
;-----------------------------------------------------------------------------
                              ; Mette le  memorie  74LS374  in  condizione  di
        MOV     DX,PRNcomd    ; attesa predisponendo il bit2 del  Registro  di
        MOV     AL,04         ; di CONTROLLO 037AH al valore 1 cioŠ ponendo  a
        OUT     DX,AL         ; "1" tutte  le  uscite  del decoder  74LS139  e
                              ; quindi a "0" le linee di ckock di tutte e 8 le
                              ; memorie 74LS374
        CALL    DeskTop       ; Organizza il piano di presentazione
        MOV     AX,2301H      ;
        MOV     BX,6745H      ; Prepara il dato a 64 bit da spedire, un byte
        MOV     CX,0AB89H     ; alla volta, alla porta parallela
        MOV     DX,0EFCDH     ;
                              ;/---------------------------------------------\
        CALL    Out64bit      ;|Memorizza il dato a 64 sulle linee di USCITA |
                              ;\---------------------------------------------/
xxx00:  CALL    KEYwait       ; Si ferma in attesa della pressione di un tasto
        AND     AL,11011111B  ; imponendo  il  ritorno  immediato  al  sistema
        CMP     AL,"Q"        ; operativo se si tratta del tasto "Q"
        JZ      _OUT          ; (cosa non strettamente necessaria..)
        JMP     SHORT xxx00   ;

_OUT:   PUSH    AX            ; Torna al DOS con la memoria liberata e con la
        CALL    RIP_cur       ; chiusura di tutti i file; cede  il  controllo
        MOV     DH,23         ; al processo padre (generalmente COMMAND.COM);
        MOV     DL,0          ; il valore posto eventualmente  in AL prima di
        CALL    SET_cur       ; uscire pu• essere testato in  uscita  con  la
        POP     AX            ; funzione 4DH  o  mediante  la  lettura  della
        MOV     AH,4CH        ; variabile DOS "ERRORLEVEL"
        INT     21H

Out64Lpt ENDP                 ; Chiusura della Procedura "Main Program"
_prog   ENDS                  ; Chiusura del Segmento di CODICE
        END INIZIO            ; Indirizzo dell'ultima istruzione da compilare