Porta Seriale - Applicazioni Software ["Dentro il Computer" di Giobe®2000]

		Come Funziona SR232 Indirizzi Base Area Comunicaz. Bios Registri Livello Hardware Livello BIOS Livello DOS Tecniche d'Interruzione Connettori Cavi Applicazioni Software Applicazioni Hardware Download INDICE
Porta Seriale

Procedure Seriali

SetInt0C - Fasi preliminari 6/6 [196 di 403]

- Gestione degli eventi seriali con la Tecnica dell'Interruzione

5.2 Procedura SetInt0C: visione globale [6 di 6]

	La procedura SetInt0C, descritta in dettaglio nelle pagine precedenti, non può mancare in nessuno dei progetti destinati alla gestione di una porta seriale con Tecnica d'Interruzione.
	Il suo codice assembly è visibile, nella sua totalità, scorrendo la barra laterale nella seguente casella di testo:

NB: se il testo nell'Area ti sembra strano
installa il font Giobe.TTF: clicca qui!!

;ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
;³                           ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿³
;³PROCEDURA  : SetInt0C      ³** VERSIONE per IRQ4 da Trasmettitore Vuoto **³³
;³                           ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ³
;³DESCRIZIONE: Questa procedura  predispone  il  computer  per  accettare  le³
;³             richieste d'interruzione generate dalla porta seriale COM1.   ³
;³ÚÄÄÄÄÄÄÄÄÄÄÄ¿                                                              ³
;³³°°°°°°°°°°°³ Questa versione abilita la richiesta di interruzione SOLO  in³
;³³°°° NB: °°°³ caso  di "Registro Trasmettitore Vuoto";   ogni  modifica  va³
;³³°°°°°°°°°°°³ operata sulla riga di programma con l'etichetta: "Cambia".   ³
;³ÀÄÄÄÄÄÄÄÄÄÄÄÙ                                                              ³
;³             Per rendere disponibile  una  procedura  di  servizio  per  le³
;³             richieste d'interruzione generate dalla  porta  seriale COM1 Š³
;³             necessario rimappare il vettore INT 0CH chiamato  a  puntarla;³
;³             per poter ripristinare in uscita le stesse condizioni  trovate³
;³             in ingresso, prima di sostituirlo, salva il valore del vettore³
;³             originale.                                                    ³
;³             Interviene sia sui registri dell'UART (azzerando  le richieste³
;³             d'interruzione pendenti e abilitando  solo  gli eventi seriali³
;³             autorizzati a interrompere, nel nostro esempio dal  ricevitore³
;³             e dal trasmettitore) sia sul controller delle interruzioni del³
;³             computer (il PIC 8259A).                                      ³
;³             Sebbene sia cosa consiglibile  la  procedura  non  provvede al³
;³             servizio di errori critici e di break: in queste condizioni la³
;³             pressione dei tasti ctrl-C o ctrl-Break imporrà un  ritorno al³
;³             DOS senza ripristinare il vettore INT 0CH originale.          ³
;ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
SetInt0C:                     ;¿La sostituzione  di  un  Vettore Š  operazione
        CLI                   ;³critica, per cui per tutto il tempo necessario
                              ;Ùle interruzioni sono disabilitate
        PUSH    ES            ;¿
        XOR     AX,AX         ;³
        MOV     ES,AX         ;³
        MOV     DI,0030H      ;³Punta   con  ES:DI  la  locazione  0000:0030H,
        LEA     SI,Old_Int0C  ;³contenente il vettore originale INT 0CH per il
        MOV     AX,ES:[DI]    ;³servizio dell'interruzione IRQ4 da COM1 o COM3
        MOV     CS:[SI],AX    ;³e con CS:SI la  variabile  locale [Old_Int0C],
        ADD     DI,2          ;³nella quale riporne il  valore,  in  attesa di
        ADD     SI,2          ;³ripristinarlo, alla fine del programma
        MOV     AX,ES:[DI]    ;³
        MOV     CS:[SI],AX    ;Ù
        MOV     AX,CS         ;¿Sostituisce  nelle  medesime  locazioni  della
        MOV     ES:[DI],AX    ;³Tabella dei Vettori (i 4  bytes  a  partire da
        SUB     DI,2          ;³0000:0030H ancora puntati da ES:DI) il vettore
        LEA     AX,ServInt0C  ;³originale INT 0CH con CS:ServInt0C,  indirizzo
        MOV     ES:[DI],AX    ;³del nuovo servizio  per  l'interuzione IRQ4 da
        POP     ES            ;ÙCOM1 o COM3 
                              ;¿La lettura dei 2  Registri di Stato  dell'UART
        MOV     DX,CS:[port_D];³(quello di Linea, [port_D] e quello del Modem,
        IN      AL,DX         ;³[port_E]) annulla tutti i bit in essi contenu-
        MOV     DX,CS:[port_E];³ti, annullando cos anche le possibili richie-
        IN      AL,DX         ;³ste  d'interruzione  pendenti  per  errori  in
                              ;Ùricezione o per presenza di CTS, DSR o RI
        MOV     DX,CS:[port_A];¿La  lettura  del  Registro  Identificatore  di
        IN      AL,DX         ;³Interrupt, [port_A], annulla anche l'eventuale
                              ;Ùsuo bit0 (se  bit0=1  significa  INT pendente)
        MOV     DX,CS:[port_8];¿La lettura del  Registro  di Ricetrasmissione,
        IN      AL,DX         ;³[port_8],  annulla  l'eventuale  richiesta  di
                              ;Ùinterrupt per "dato seriale disponibile"
                              ;¿Per poter abilitare  con  sicurezza gli eventi
        MOV     DX,CS:[port_B];³seriali autorizzati ad interrompere è necessa-
        IN      AL,DX         ;³rio essere certi che l'indirizzo [port_9] stia
        AND     AL,01111111B  ;³puntando il  Registro  di  Abilitazione  delle
        OUT     DX,AL         ;³Interruzioni e NON uno dei 2 Registri Divisori
                              ;³di Baud Rate, ponendo a 0 il bit7 del Registro
                              ;Ùdi Controllo Linea, [port_B]
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;¿Stabilisce  gli  eventi  seriali autorizzati a
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;³richiedere servizio d'interruzione, ponendo  a
;° NB: cambia qui gli eventi °;³1 i bit ad essi  associati,  nel  Registro  di
;° che possono interrompere..°;³Abilitazione delle Interruzioni, [port_9]:
;°°°°°°°°°°°°°°°°°°°°°°||||°°°;³        ÚÄ7Ä6Ä5Ä4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
Cambia: MOV     AL,00000010B  ;³[port_9]³ 0 0 0 0 ³ 0 ³ 0 ³ 1 ³ 0 ³    02H
        MOV     DX,CS:[port_9];³        ÀÄÄÄÄÄÄÄÄÄÁÄnoÁÄnoÁÄsiÁÄnoÙ
        OUT     DX,AL         ;³Variaz. Stato LineaÄÙ   ³   ³   ÀÄ Dato pronto
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;³Variaz. Stato ModemÄÄÄÄÄÙ   ³     in Ricezione
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;³Dato trasmesso,Trasm. vuotoÄÙ
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;³I bit degli eventi non  autorizzati  ad inter-
;°°°°°°°°°°°°°°°°°°°°°°°°°°°°°;Ùrompere DEVONO essere lascati a 0 logico
                              ;¿Per poter rendere possibili le interruzioni da
                              ;³parte dell'UART  Š  necessario  forzare a 1 la
                              ;³linea OUT2 (pin31 UART); questa situazione  si
                              ;³ottiene portando a 1  il bit3 del  Registro di
                              ;³Controllo Modem, [port_C] e permette il colle-
        MOV     AL,00001011B  ;³gamento a livello hardware  della  linea  INTR
        MOV     DX,CS:[port_C];³(pin30 dell'UART) alla linea IRQ4 del control-
        OUT     DX,AL         ;³ler delle interruzioni, 8259A;  in  condizioni
                              ;³normali anche le linee DTR (pin33 UART) e  RTS
                              ;³(pin32 UART) devono  essere  attive (cioŠ a 1)
                              ;³per cui saranno a 1  anche  i rispettivi  bit0
                              ;³e bit1, mentre  il  bit4 (Lookback Mode)  deve
                              ;³essere ovviamente a 0
                              ;³        ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂÄ4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
                              ;³[port_C]³ 0 ³ 0 ³ 0 ³ 0 ³ 1 ³ 0 ³ 1 ³ 1 ³ 0BH
                              ;³        ÀÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÁÄÄÄÙ
                              ;³non usatiÄÁÄÄÄÁÄÄÄÙ   ³   ³   ³   ³   ÀDTR on
                              ;³no LookBack ModeÄÄÄÄÄÄÙ   ³   ³   ÀÄÄÄÄRTS on
                              ;ÙINT   abilitate ÄÄÄÄOUT2ÄÄÙ   ÀOUT1Änon usata
                              ;¿Non rimane ora che intervenire sul  controller
                              ;³delle interruzioni del computer (il PIC 8259A)
                              ;³per settare il bit corrispondente a COM1,  nel
        IN      AL,_8259mk    ;³suo Registro di Abilitazione  Interruzioni HW,
        MOV    CS:[Dep8259],AL;³[0021H]. La linea  IRQ4 (in  arrivo da COM1) Š
        AND     AL,11101111B  ;³abilitata forzando  a  0 il bit4;  la  tecnica
        OUT     _8259mk,AL    ;³utilizzata non altera i valori degli altri bit
                              ;³di questo Registro, lasciando abilitate  altre
                              ;³eventuali  fonti  di  interruzione (di  solito
                              ;³almeno il Timer di Sistema e la Tastiera). Una
                              ;³copia dello stato originale di questo Registro
                              ;³Š salvata nella variabile locale [Dep8259], in
                              ;³attesa di ripristinarlo alla fine del programm
                              ;³       ÚÄ7ÄÂÄ6ÄÂÄ5ÄÂÄ4ÄÂÄ3ÄÂÄ2ÄÂÄ1ÄÂÄ0Ä¿
                              ;³[0021H]³ 1 ³ 1 ³ 1 ³ 0 ³ 1 ³ 1 ³ 0 ³ 0 ³  ECH
                              ;³       ÀÄnoÁÄnoÁÄnoÁÄsiÁÄnoÁÄnoÁÄsiÁÄsiÙ TIMER
                              ;³LPT1 IRQ7ÄÙ   ³   ³   ³   ³   ³   ³   ÀÄÄÄIRQ0
                              ;³DISK IRQ6ÄÄÄÄÄÙ   ³   ³   ³   ³   ÀÄÄIRQ1 KEYB
                              ;³LPT2 IRQ5ÄÄÄÄÄÄÄÄÄÙ   ³   ³   ÀÄÄÄÄÄÄIRQ2 USER
                              ;ÙCOM1 IRQ4ÄÄÄÄÄÄÄÄÄÄÄÄÄÙ   ÀÄÄÄÄÄÄÄÄÄÄIRQ3 COM2
        RET

	Esso è dedicato ad una richiesta d'interruzioni IRQ4, generata da COM1 o COM3, esclusivamente in presenza dell'evento seriale trasmettitore vuoto, adatto al progetto di gestione della Trasmissione sotto Interrupt (TxD2Com1 per la COM1 e TxD2Com2 per la COM2) disponibile partendo dall'elenco di questa pagina).
	Le modifiche da apportare per richieste generate da COM2 o COM4 e/o da altri eventi seriali (per dato ricevuto pronto, ma anche per variazioni dello Stato della Linea o del Modem) sono evidenziate nel testo delle pagine precedenti.

	Porta Seriale			SetInt0C - Fasi preliminari 6/6
	196 di 403

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403

Seriale »

^Home

Pascal|Manuali|Tabelle|Schede
Tutorial Assembly|Palestra Assembler

Aggiungi Giobe®2000 ai preferiti

Motore
Ricerca

Rendi Giobe®2000 pagina di Default